Asynchronous FTP Download

The Chilkat FTP component supports asynchronous uploads and downloads. This examples demonstrates doing a download in a background thread. The download is started by calling AsyncGetFileStart. While the download is in progress, your program may do other tasks. You may periodically check the AsyncFinished property to determine when the transfer is finished. The example below provides the remainder of the details.

Download Chilkat FTP2 ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "www.secureftp-test.com"
ftp.Username = "test"
ftp.Password = "test"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

localFilename = "hamlet.xml"
remoteFilename = "hamlet.xml"

'  Begin the download in a background thread.
'  Only 1 background upload or download may be active at any time.
'  (per instance of an FTP object)
success = ftp.AsyncGetFileStart(remoteFilename,localFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  The application is now free to do anything else
'  while the file is downloading.
'  For this example, we'll simply sleep and periodically
'  check to see if the transfer if finished.  While checking
'  however, we'll report on the progress in both number
'  of bytes tranferred and performance in bytes/second.
Do While ftp.AsyncFinished <> 1

    outFile.WriteLine(ftp.AsyncBytesReceived _
         & " bytes received")
    outFile.WriteLine(ftp.DownloadRate & " bytes per second")

    '  Sleep 1 second.
    ftp.SleepMs 1000
Loop

'  Did the download succeed?
If (ftp.AsyncSuccess = 1) Then
    MsgBox "File Downloaded!"
Else
    '  The error information for asynchronous ops
    '  is in AsyncLog as opposed to LastErrorText
    MsgBox ftp.AsyncLog
End If

ftp.Disconnect 
outFile.Close