Customize Titles and Captions on Self-Extracting EXE Dialogs

Customize titles and captions on all self-extracting EXE dialogs.

Download Chilkat Zip ActiveX

set zip = CreateObject("Chilkat.Zip2")

'  Any string unlocks the component for the 1st 30-days.
success = zip.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Initialize the zip object.  Because we're creating
'  a self-extracting EXE in this example, the filename
'  passed to NewZip will never actually be created.
success = zip.NewZip("notUsed.zip")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

'  Append a directory tree.  The AppendFiles does
'  not read the file contents or append them to the zip
'  object in memory.  It simply appends references
'  to the files so that when WriteExe (or WriteZipAndClose,
'  or WriteZip, etc.) is called, the files are compressed
'  and added to the archive.
recurse = 1
zip.AppendFiles "c:/temp/a/*",recurse

'  The zip.ExeTitle and zip.ExeUnzipCaption properties can be
'  set to customize the title and caption for the main dialog
'  presented by the self-extracting EXE.
'  A new method (SetExeConfigParam) provides the ability
'  to set the titles and captions for all dialogs:
zip.SetExeConfigParam "MainTitle","This is the main title"
zip.SetExeConfigParam "MainCaption","This is the main caption"

'  A finish notification dialog is displayed if the
'  ExeFinishNotifier property is set:
zip.ExeFinishNotifier = 1
zip.SetExeConfigParam "FinTitle","This is the finish notifier title"
zip.SetExeConfigParam "FinCaption","This is the finish notifier caption"

'  A password challenge dialog is shown if the EXE is encrypted.
zip.Encryption = 4
zip.EncryptKeyLength = 128
zip.SetPassword "test"
zip.SetExeConfigParam "PwTitle","This is the pasword dialog title"
zip.SetExeConfigParam "PwCaption","This is the password dialog caption"

'  During the EXE self-extract, a progress dialog is displayed *if* the main dialog
'  is suppressed. In this example, the main dialog is not suppressed, so the
'  progress dialog is not displayed.  (A progress bar shows in the main dialog during
'  EXE extract.)
'  If a progress dialog was displayed, this is how the title and caption would be customized:
zip.SetExeConfigParam "ProgressTitle","This is the progress dialog title"
zip.SetExeConfigParam "ProgressCaption","This is the progress dialog caption"

'  Write "mySfx.exe"
success = zip.WriteExe("mySfx.exe")
If (success <> 1) Then
    MsgBox zip.LastErrorText
    WScript.Quit
End If

MsgBox "EXE Created!"