Save an Email Attachment using a Specific Filename

Download Chilkat Email ActiveX

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Demonstrates how to save an email attachment using a specific filename, regardless of the filename in the email.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Create a MailMan or Imap object first for the purpose
'  of unlocking the component. (Only one is necessary)
set mailman = CreateObject("Chilkat.MailMan2")
mailman.UnlockComponent "anything for 30-day trial"
set imap = CreateObject("Chilkat.Imap")
imap.UnlockComponent "anything for 30-day trial"

set email = CreateObject("Chilkat.Email2")

'  Load an email object containing attachments.
'  This .eml can be downloaded from:
'  http://www.example-code.com/testData/HtmlEmail.eml

success = email.LoadEml("HtmlEmail.eml")
If (success <> 1) Then
    MsgBox email.LastErrorText
    WScript.Quit
End If

'  List the attachment filenames:
'  This email has two attachments: logo.jpg and faxCover.doc

For i = 0 To email.NumAttachments - 1
    outFile.WriteLine(email.GetAttachmentFilename(i))
Next

'  Let's say we want to save the 1st attachment as "pic.jpg",
'  and the 2nd attachment as "cover.doc".
'  Call SetAttachmentFilename for both:
email.SetAttachmentFilename 0,"pic.jpg"
email.SetAttachmentFilename 1,"cover.doc"

'  The SaveAttachedFile method allows you to specify the directory
'  where the attachment is saved.  To save to the current working
'  directory, pass a "." for the directory path.  This code
'  saves each attachment to the current working directory:
email.SaveAttachedFile 0,"."
email.SaveAttachedFile 1,"."

'  Alternatively, we could save all the attachments in a single
'  call.  The argument to SaveAllAttachments is the directory
'  path.  In this case, the filenames set by SetAttachmentFilename
'  are used:
email.SaveAllAttachments "myAttachments"

MsgBox "Finished!"

outFile.Close