(VBScript) Deflate String

Compresses a string using the Deflate compression algorithm.

Download Chilkat Compression ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set compress = CreateObject("Chilkat.Compression")

'  Any string argument automatically begins a 30-day trial.
success = compress.UnlockComponent("30-day trial")
If (success <> 1) Then
    outFile.WriteLine(compress.LastErrorText)
    WScript.Quit
End If

compress.Algorithm = "deflate"

'  Create a long string to deflate.
strData = "abcdefg1122334455667788"
strData = strData & vbCrLf
For i = 0 To 99
    strData = strData & "abcdefg1122334455667788"
    strData = strData & vbCrLf
Next

'  Depending on the programming language, the string
'  may be Unicode.  Tell the component to convert to
'  ansi (1-byte/char) prior to compression:
compress.Charset = "ansi"

'  Compressed data is binary, meaning that all byte values
'  from 0 to 255 are possible.  The result would not be
'  a printable string.  To receive a printable string (us-ascii),
'  the resultant compressed data should be encoded using
'  an encoding such as base64.  Set the EncodingMode
'  property to determine the output encoding:
'  (Valid choices are "base64", "hex", "url", and others)
compress.EncodingMode = "base64"

'  Note: Base64 encoding expands the compressed data by
'  4/3rds because each 3 bytes of binary data are represented
'  by 4 printable chars.  Hex, for example, doubles the output
'  size because each byte is represented by 2 printable chars.

'  Deflate the string:

deflatedStr = compress.CompressStringENC(strData)
If (deflatedStr = vbNullString ) Then
    outFile.WriteLine(compress.LastErrorText)
    WScript.Quit
End If

'  Display the deflated string.
'  The result will be:
'  S0xKTklNSzc0NDIyNjYxMTU1MzM3t7Dg5UoclRiVGJUYlRiVGJUYlRiVGJUYchIA
outFile.WriteLine(deflatedStr)

'  Decompress back to the original:

strOriginal = compress.DecompressStringENC(deflatedStr)

'  Display the uncompressed original:
outFile.WriteLine("--- Original ---")
outFile.WriteLine(strOriginal)
outFile.Close