Sign with .pfx to create .p7s, Verify with .cer

VBScript example to sign a file using a .pfx and creating a .p7s file as output. It then uses a .cer file to verify the signature.

Download Chilkat Crypt ActiveX

set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    WScript.Quit
End If

set certStore = CreateObject("Chilkat.CertStore")
success = certStore.LoadPfxFile("chilkat.pfx","myPfxPassword")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

Set cert = certStore.FindCertBySubjectCN("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox "Failed to find certificate"
    WScript.Quit
End If

'  We can explicitly choose hash/encryption algorithms using a CSP.
set csp = CreateObject("Chilkat.Csp")
csp.SetProviderMicrosoftEnhanced 
csp.SetHashAlgorithm "sha-1"

'  Tell the crypt component to use this cert and this CSP.
crypt.SetSigningCert cert
crypt.SetCSP csp

'  We can sign any type of file, creating a .p7s as output:
success = crypt.CreateP7S("hamlet.xml","hamlet.p7s")
If (success = 1) Then
    MsgBox "Signature created."
Else
    MsgBox crypt.LastErrorText
End If

'  Verify and restore the original file:
'  Use a cert from a .cer file (which only contains the public key)
set cert2 = CreateObject("Chilkat.Cert")
success = cert2.LoadFromFile("chilkat.cer")
If (success <> 1) Then
    MsgBox cert2.LastErrorText
    WScript.Quit
End If

crypt.SetVerifyCert cert2

success = crypt.VerifyP7S("hamlet.xml","hamlet.p7s")
If (success = 1) Then
    MsgBox "Signature verified."
Else
    MsgBox crypt.LastErrorText
End If