(VBScript) Sign a File to Create a .p7m File (using a PFX)

VBScript example to sign a file creating a .p7m file as output. The .p7m contains the signed contents of the original file. It can be verified and restored by calling VerifyP7M.

Download Chilkat Crypt ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

'  Use a digital certificate and private key from a PFX file (.pfx or .p12).
signingCertSubject = "Acme Inc"
pfxFilename = "/Users/chilkat/testData/pfx/acme.pfx"
pfxPassword = "test123"

set certStore = CreateObject("Chilkat.CertStore")
success = certStore.LoadPfxFile(pfxFilename,pfxPassword)
If (success <> 1) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubjectCN(signingCertSubject)
If (cert Is Nothing ) Then
    outFile.WriteLine("Failed to find certificate by subject common name.")
    WScript.Quit
End If

'  Tell the crypt component to use this cert.
crypt.SetSigningCert cert

'  We can sign any type of file, creating a .p7m as output:
inFile = "/Users/chilkat/testData/pdf/sample.pdf"
outputFile = "/Users/chilkat/testData/p7m/sample.pdf.p7m"
success = crypt.CreateP7M(inFile,outputFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)

    WScript.Quit
End If

'  Verify and restore the original file:
crypt.SetVerifyCert cert

inFile = outputFile
outputFile = "/Users/chilkat/testData/pdf/restored.pdf"

success = crypt.VerifyP7M(inFile,outputFile)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)

    WScript.Quit
End If

MsgBox "Success!"
outFile.Close