Decrypt P7M using PFX to get MIME

Demonstrates how to decrypt a .p7m (PKCS7) binary file using a certificate and private key from a PFX file. The result of the decryption (in this case) is MIME text that may be loaded into a Chilkat MIME object.

Note: Any type of file or data may be encrypted to produce a .p7m (PKCS7) encrypted file. This example was prompted by a customer needing to decrypt a MIME message. The final step of loading the decrypted text into a MIME object would be skipped if decrypting something other than MIME..

Download Chilkat Crypt ActiveX

Download Chilkat MIME ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    WScript.Quit
End If

'  Read the P7M file into memory.
p7mData = crypt.ReadFile("encrypted.p7m")

'  Setup the crypt object:

'  Indicate that public-key decryption is to be used.
crypt.CryptAlgorithm = "pki"

'  Add a PFX file to allow the crypt object to find
'  the certificate and private key needed for decryption
pfxFilePath = "myPfx.pfx"
pfxPassword = "secret"
success = crypt.AddPfxSourceFile(pfxFilePath,pfxPassword)
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    WScript.Quit
End If

'  Assuming the decrypted data will be text, decrypt to
'  a string.
mimeText = crypt.DecryptString(p7mData)
If (mimeText = vbNullString ) Then
    MsgBox crypt.LastErrorText
    WScript.Quit
End If

'  Note: Chilkat Crypt and Chilkat MIME are separate products.
'  To use both objects, one would license the "Chilkat Bundle",
'  which provides licenses to all existing Chilkat products.
'  This is less expensive than licensing each of the two products separately.

set mime = CreateObject("Chilkat.Mime")

success = mime.UnlockComponent("Anyting for 30-day trial")
If (success <> 1) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

'  Load the MIME text into the MIME object.
success = mime.LoadMime(mimeText)
If (success <> 1) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

'  Save the MIME to a file:
success = mime.SaveMime("outMime.txt")
If (success <> 1) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

'  Success!  Output the MIME text:
outFile.WriteLine(mime.GetMime())


outFile.Close