Use Certificate and Private Key PEM Files to Create a Digital Signature

Demonstrates how to load a digital certificate from a PEM file, load it's corresponding private key from a PEM file, save the private key to a key container (if necessary), link the certificate to the key container, and use it to create a digital signature.

Download Chilkat Crypt ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set cert = CreateObject("Chilkat.Cert")

'  Load the cert from a PEM file;
cert.LoadFromFile "cert.pem"

set pkey = CreateObject("Chilkat.PrivateKey")

'  Load the private key from an RSA PEM file:
pkey.LoadPemFile "pkey_rsa.pem"

success = cert.SetPrivateKey(pkey)
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

'  Use Chilkat Crypt (a non-freeware component) to create
'  a digital signature using the certificate w/ private key:
set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

'  Tell the crypt component to use this cert.
crypt.SetSigningCert cert

'  A PKCS7 signature for any type of file content can be created:
success = crypt.CreateP7S("license.rtf","license.p7s")
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(crypt.LastErrorText)

'  Verify and restore the original file:
crypt.SetVerifyCert cert

success = crypt.VerifyP7S("license.rtf","license.p7s")
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

MsgBox "Success!"


outFile.Close