Export Private Key to PKCS8, PEM, DER, XML

Demonstrates how to export a digital certificate's private key to RSA PEM or DER, PKCS8 PEM or DER, or XML.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set cert = CreateObject("Chilkat.Cert")

'  Th LoadByCommonName method searches the Windows
'  Current User Certificate Store and Local Machine Certificate
'  Store for a certificate whose common name (CN) matches
'  the argument:

success = cert.LoadByCommonName("Chilkat Software, Inc.")
If (success = 0) Then
    MsgBox "Failed to find certificate!"
Else

    '  Get the PrivateKey object:

    Set pkey = cert.ExportPrivateKey()
    If (Not (pkey Is Nothing )) Then

        '  Export the private key to an RSA DER file:
        pkey.SaveRsaDerFile "pkey_rsa.der"

        '  Export to a PKCS8 DER file:
        pkey.SavePkcs8File "pkey_pkcs8.der"

        '  Export to an RSA PEM file:
        pkey.SaveRsaPemFile "pkey_rsa.pem"

        '  Export to a PKCS8 PEM file:
        pkey.SavePkcs8PemFile "pkey_pkcs8.pem"

        '  Export to XML:
        pkey.SaveXmlFile "pkey.xml"

        '  Get PKCS8 PEM string:
        outFile.WriteLine("PKCS8 PEM Private Key:")
        outFile.WriteLine(pkey.GetPkcs8Pem())

        '  Get RSA PEM string:
        outFile.WriteLine("RSA PEM Private Key:")
        outFile.WriteLine(pkey.GetRsaPem())

    Else
        MsgBox "No private key found!"
    End If

End If

'  The Chilkat Certificate, Certificate Store, Private Key,
'  Public Key, and Key Container classes / objects are freeware.

'  They are used by and included with the Chilkat Email,
'  Crypt, S/MIME, and other commercial Chilkat components.

outFile.Close