RSA Signature/Verify with .key and .cer

Demonstrates how to use a .key file (private key) and digital certificate (.cer, public key) to create and verify an RSA signature.

Download Chilkat .NET for 4.0 Framework

Download Chilkat .NET for 64-bit 4.0 Framework (x64)

Download Chilkat .NET for 2.0 / 3.5 Framework

Download Chilkat .NET for 64-bit 2.0 / 3.5 Framework (x64)

Download Chilkat .NET for 1.0 / 1.1 Framework

Dim privKey As New Chilkat.PrivateKey()

Dim success As Boolean

'  Load the private key from an RSA .key file:
success = privKey.LoadPemFile("privateKey.key")
If (success <> true) Then
    MsgBox(privKey.LastErrorText)
    Exit Sub
End If


Dim privKeyXml As String
'  Get the private key in XML format:
privKeyXml = privKey.GetXml()

Dim rsa As New Chilkat.Rsa()

'  Any string argument automatically begins the 30-day trial.

success = rsa.UnlockComponent("30-day trial")
If (success <> true) Then
    MsgBox(rsa.LastErrorText)
    Exit Sub
End If


'  Import the private key into the RSA component:
success = rsa.ImportPrivateKey(privKeyXml)
If (success <> true) Then
    MsgBox(rsa.LastErrorText)
    Exit Sub
End If


'  Create the signature as a hex string:
rsa.EncodingMode = "hex"

'  If some other non-Chilkat application or web service is going to be verifying
'  the signature, it is important to match the byte-ordering.
'  The LittleEndian property may be set to True
'  for little-endian byte ordering,
'  or False  for big-endian byte ordering.
'  Microsoft apps typically use little-endian, while
'  OpenSSL and other services (such as Amazon CloudFront)
'  use big-endian.
rsa.LittleEndian = false

Dim strData As String
strData = "This is the string to be signed."

'  Sign the string using the sha-1 hash algorithm.
'  Other valid choices are "md2", "sha256", "sha384",
'  "sha512", and "md5".
Dim hexSig As String
hexSig = rsa.SignStringENC(strData,"sha-1")

TextBox1.Text = TextBox1.Text & hexSig & vbCrLf

'  Load a digital certificate from a .cer file:
Dim cert As New Chilkat.Cert()

success = cert.LoadFromFile("myCert.cer")
If (success <> true) Then
    MsgBox(cert.LastErrorText)
    Exit Sub
End If


Dim pubKey As Chilkat.PublicKey

pubKey = cert.ExportPublicKey()


'  Now verify using a separate instance of the RSA object:
Dim rsa2 As New Chilkat.Rsa()

'  Import the public key into the RSA object:
success = rsa2.ImportPublicKey(pubKey.GetXml())
If (success <> true) Then
    MsgBox(rsa2.LastErrorText)
    Exit Sub
End If




'  The signature is a hex string, so make sure the EncodingMode is correct:
rsa2.EncodingMode = "hex"

'  Verify the signature:
success = rsa2.VerifyStringENC(strData,"sha-1",hexSig)
If (success <> true) Then
    MsgBox(rsa2.LastErrorText)
    Exit Sub
End If


MsgBox("Success.")