Search IMAP Mailbox for Email Matching Criteria

Download Chilkat .NET for 4.0 Framework

Download Chilkat .NET for 64-bit 4.0 Framework (x64)

Download Chilkat .NET for 2.0 / 3.5 Framework

Download Chilkat .NET for 64-bit 2.0 / 3.5 Framework (x64)

Download Chilkat .NET for 1.0 / 1.1 Framework

Searching an IMAP mailbox for messages that match search criteria.

Dim imap As New Chilkat.Imap()

Dim success As Boolean

' Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


' Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


' Login
success = imap.Login("admin@chilkatsoft.com","*myPassword5*")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If



Dim messageSet As Chilkat.MessageSet
' We can choose to fetch UIDs or sequence numbers.
Dim fetchUids As Boolean
fetchUids = true

' Here are examples of different search criteria:

' Return all messages.
Dim allMsgs As String
allMsgs = "ALL"

' Search for already-answered emails.
Dim answered As String
answered = "ANSWERED"

' Search for messages on a specific date.
' The date string is DD-Month-YYYY where Month is
' Jan, Feb, Mar, Apr, May, Jun, Jul, Aug, Sep, Oct, Nov, or Dec.
Dim onDate As String
onDate = "SENTON 05-Mar-2007"

' Search for messages between two dates.  SENTBEFORE
' finds emails sent before a date, and SENTSINCE finds
' email sent on or after a date.  The "AND" operation
' is implied by joining criteria, separated by spaces.
Dim betweenDates As String
betweenDates = "SENTSINCE 01-Mar-2007 SENTBEFORE 05-Mar-2007"

' Another example of AND: find all unanswered emails
' sent after 04-Mar-2007 with "Problem" in the subject:
Dim complexSearch1 As String
complexSearch1 = "UNANSWERED SENTSINCE 04-Mar-2007 Subject ""Problem"""

' Find messages with a specific string in the body:
Dim bodySearch As String
bodySearch = "BODY ""problem solved"""

' Using OR.  The syntax is OR <criteria1> <criteria2>.
' The "OR" comes first, followed by each criteria.
' For example, to match all emails with "Help" or "Question" in the subject.
' You'll notice that literal strings may be quoted or unquoted.
' If a literal contains SPACE characters, quote it:
Dim orSearch As String
orSearch = "OR SUBJECT Help SUBJECT Question"

' ----------------------------------------------
' Strings are case-insensitive when searching....
' ----------------------------------------------

' Find all emails sent from yahoo.com addresses:
Dim fromSearch As String
fromSearch = "FROM yahoo.com"
' Find all emails sent from anyone with "John" in their name:
Dim johnSearch As String
johnSearch = "FROM John"

' Find emails with the RECENT flag set:
Dim recentSearch As String
recentSearch = "RECENT"

' Find emails that don't have the recent flag set:
Dim notRecentSearch As String
notRecentSearch = "NOT RECENT"
' This is synonymous with "OLD":
Dim oldSearch As String
oldSearch = "OLD"

' Find all emails marked for deletion:
Dim markedForDeleteSearch As String
markedForDeleteSearch = "DELETED"

' Find all emails having a specified header field with a value
' containing a substring:
Dim headerSearch As String
headerSearch = "HEADER DomainKey-Signature paypal.com"

' Find any emails having a specific header field.  If the
' 2nd argument to the "HEADER" criteria is an empty string,
' any email having the header field is returned regardless
' of the header field's content.
' Find any emails with a DomainKey-Signature field:
Dim headerExistsSearch As String
headerExistsSearch = "HEADER DomainKey-Signature """""

' Find NEW emails: these are emails that have the RECENT flag
' set, but not the SEEN flag:
Dim newSearch As String
newSearch = "NEW"

' Find emails larger than a certain number of bytes:
Dim sizeLargerSearch As String
sizeLargerSearch = "LARGER 500000"

' Find emails marked as seen or not already seen:
Dim seenSearch As String
seenSearch = "SEEN"
Dim notSeenSearch As String
notSeenSearch = "NOT SEEN"

' Find emails having a given substring in the TO header field:
Dim toSearch As String
toSearch = "TO support@chilkatsoft.com"
' A more long-winded way to do the same thing:
Dim toSearch2 As String
toSearch2 = "HEADER TO support@chilkatsoft.com"

' Find emails smaller than a size in bytes:
Dim smallerSearch As String
smallerSearch = "SMALLER 30000"

' Find emails that have a substring anywhere in the header
' or body:
Dim fullSubstringSearch As String
fullSubstringSearch = "TEXT ""Zip Component"""


' Pass any of the above strings here to test a search:
messageSet = imap.Search(orSearch,fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


' Fetch the email headers into a bundle object:
Dim bundle As Chilkat.EmailBundle
bundle = imap.FetchHeaders(messageSet)
If (bundle Is Nothing ) Then

    MsgBox(imap.LastErrorText)
    Exit Sub
End If


' Display the Subject and From of each email.
Dim i As Long
For i = 0 To bundle.MessageCount - 1
    Dim email As Chilkat.Email
    email = bundle.GetEmail(i)

    TextBox1.Text = TextBox1.Text & email.GetHeaderField("Date") & vbCrLf
    TextBox1.Refresh()
    TextBox1.Text = TextBox1.Text & email.Subject & vbCrLf
    TextBox1.Refresh()
    TextBox1.Text = TextBox1.Text & email.From & vbCrLf
    TextBox1.Refresh()
    TextBox1.Text = TextBox1.Text & "--" & vbCrLf
    TextBox1.Refresh()


Next

' Disconnect from the IMAP server.
imap.Disconnect()