Read S/MIME Encrypted Email

Read S/MIME encrypted email.

Download Chilkat .NET for 2.0 / 3.5 Framework

Download Chilkat .NET for 1.0 / 1.1 Framework

Dim imap As New Chilkat.Imap()

Dim success As Boolean

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


'  Login
success = imap.Login("myLogin","myPassword")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> true) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


'  The AutoUnwrapSecurity method controls whether signed/encrypted emails are automatically
'  decrypted and/or verified.

'  When set to True, which is the default, security envelopes are automatically "unwrapped"
'  when a message is retrieved from the server. Signed emails are automatically verified, and
'  encrypted emails are automatically decrypted, restoring the email to the original state before
'  signing and/or encrypting. Information about the signing and encrypting certificates can be
'  retrieved from the Email object (methods: GetSignedByCert, GetEncryptedByCert;
'  properties: SignedBy, EncryptedBy, SignaturesValid, Decrypted, ReceivedSigned,
'  ReceivedEncrypted).

'  This example will explicity set AutoUnwrapSecurity to True, even though it's
'  already the default value:
imap.AutoUnwrapSecurity = true


'  The NumMessages property contains the number of messages in the selected mailbox.
Dim numToFetch As Long
numToFetch = imap.NumMessages
'  Download all the email in the Inbox.
Dim bundle As Chilkat.EmailBundle
bundle = imap.FetchSequence(1,numToFetch)
If (bundle Is Nothing ) Then
    MsgBox(imap.LastErrorText)
    Exit Sub
End If


'  Loop over the bundle,
Dim i As Long
For i = 0 To bundle.MessageCount - 1
    Dim email As Chilkat.Email
    email = bundle.GetEmail(i)

    TextBox1.Text = TextBox1.Text & email.From & vbCrLf
    TextBox1.Text = TextBox1.Text & email.Subject & vbCrLf

    '  At this point, if the email was signed and/or encrypted, it is already "unwrapped", i.e.
    '  the email is already decrypted and in a state as if it were never signed or encrypted.
    '  You may check to see if the email was received encrypted or signed, and if so,
    '  whether it was successfully unwrapped and who signed or encrypted it:
    If (email.ReceivedEncrypted = true) Then

        TextBox1.Text = TextBox1.Text & "This email was encrypted when received." & vbCrLf
        If (email.Decrypted = true) Then
            TextBox1.Text = TextBox1.Text & "This email was successfully decrypted.  It was encrypted by:" & vbCrLf
            TextBox1.Text = TextBox1.Text & email.EncryptedBy & vbCrLf
        Else
            TextBox1.Text = TextBox1.Text & "This email was not decrypted." & vbCrLf
        End If

    End If

    If (email.ReceivedSigned = true) Then

        TextBox1.Text = TextBox1.Text & "This email was signed when received." & vbCrLf
        If (email.SignaturesValid = true) Then
            TextBox1.Text = TextBox1.Text & "The signature was verified.  It was signed by:" & vbCrLf
            TextBox1.Text = TextBox1.Text & email.SignedBy & vbCrLf
        Else
            TextBox1.Text = TextBox1.Text & "The signature verification failed." & vbCrLf
        End If

    End If


    '  The email's body, HTML body, attachments, etc.
    '  are decrypted and available just like any non-encrypted email.

    TextBox1.Text = TextBox1.Text & "--" & vbCrLf

Next

'  Disconnect from the IMAP server.
imap.Disconnect()