Visual Basic 6.0

OneDrive -- List Large Directory

See more OneDrive Examples

Demonstrates how to get the entire collection of DriveItem children when the collection is large and multiple pages need to be requested. To test this example, I created a DriveItem with 450 children.

Note: This example requires Chilkat v9.5.0.97 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses the OAuth client credentials flow.
' See How to Create an Azure App Registration for OAuth 2.0 Client Credentials

' Use your client ID, client secret, and tenant ID in the following lines
Dim json As New ChilkatJsonObject
success = json.UpdateString("client_id","2871da2c-8176-4b7f-869b-2311aa82e743")
success = json.UpdateString("client_secret","2hu9Q~r5QuryUcEkNbg1btLtnfU1VUXzhSCG6brH")
success = json.UpdateString("scope","https://graph.microsoft.com/.default")
success = json.UpdateString("token_endpoint","https://login.microsoftonline.com/114d7ed6-71bf-4dbe-a866-748364121bf2/oauth2/v2.0/token")

Dim http As New ChilkatHttp
http.AuthToken = json.Emit()

' This example will get the DriveItems in /lots-of-files, which has 450 children..
success = http.SetUrlVar("item_path","/lots-of-files")
success = http.SetUrlVar("user_id","4fe732c3-322e-4a6b-b729-2fd1eb5c6104")

Dim resp As String
Dim i As Long
Dim numItems As Long

json.EmitCompact = 0

' This loop will download DriveItems in sets of 25 until no more exist.
Dim bGetMore As Long
bGetMore = 1
' (Add the $top query parameter to define the page size, i.e. the max number of results to return).
Dim nextLink As String
nextLink = "https://graph.microsoft.com/v1.0/users/{$user_id}/drive/root:{$item_path}:/children?$top=25"

Do While (bGetMore = 1)

    ' Get the next chunk of DriveItems
    resp = http.QuickGetStr(nextLink)
    If (http.LastMethodSuccess <> 1) Then
        Debug.Print http.LastErrorText
        Exit Sub
    End If

    ' The response should be JSON.
    success = json.Load(resp)

    ' A successful response should return a status code of 200.
    If (http.LastStatus <> 200) Then
        Debug.Print json.Emit()
        Debug.Print "Response status = " & http.LastStatus
        Exit Sub
    End If

    ' Iterate over the DriveItems in the JSON response:
    i = 0
    numItems = json.SizeOfArray("value")
    Do While i < numItems
        json.I = i
        Debug.Print "name: " & json.StringOf("value[i].name")
        i = i + 1
    Loop

    ' If a nextLink was included in the JSON, use it to get the next set of 50 DriveItems.
    ' Otherwise, exit the loop.
    If (json.HasMember("""@odata.nextLink""") = 1) Then
        nextLink = json.StringOf("""@odata.nextLink""")
        Debug.Print "nextLink: " & nextLink
    Else
        bGetMore = 0
    End If

Loop