Visual Basic 6.0

Generate ECDSA Key and Get Details as XML

See more ECC Examples

Demonstrates how to generate an ECDSA key and gets the parts as XML. Visual Basic 6.0

Dim success As Long
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ecc As New ChilkatEcc

' Generate a random ECC private key on the secp256k1 curve.
' Chilkat also supports other curves, such as secp384r1, secp521r1, and secp256r1.

' Create a Fortuna PRNG and seed it with system entropy.
' This will be our source of random data for generating the ECC private key.
Dim fortuna As New ChilkatPrng
Dim entropy As String
entropy = fortuna.GetEntropy(32,"base64")
success = fortuna.AddEntropy(entropy,"base64")

Dim privKey As New PrivateKey
success = ecc.GenKey("secp256k1",fortuna,privKey)
If (success = 0) Then
    Debug.Print ecc.LastErrorText
    Exit Sub
End If

' An EC private key has this ASN.1
' ECPrivateKey ::= SEQUENCE {
'     version        INTEGER { ecPrivkeyVer1(1) } (ecPrivkeyVer1),
'     privateKey     OCTET STRING,
'     parameters [0] ECParameters {{ NamedCurve }} OPTIONAL,
'     publicKey  [1] BIT STRING OPTIONAL (This is the ANSI X9.63 public key format.)

Dim asn As New ChilkatAsn
success = asn.LoadEncoded(privKey.GetPkcs1ENC("base64"),"base64")
If (success <> 1) Then
    Debug.Print asn.LastErrorText
    Exit Sub
End If

Dim xml As New ChilkatXml
success = xml.LoadXml(asn.AsnToXml())

Debug.Print xml.GetXml()

' The XML looks like this:
' <?xml version="1.0" encoding="utf-8" ?>
' <sequence>
'     <int>01</int>
'     <octets>JgJvBG+3wletkJab8iXAkpz0O8/AgWZSpkYVcB7SpnU=</octets>
'     <contextSpecific tag="0" constructed="1">
'         <oid>1.3.132.0.10</oid>
'     </contextSpecific>
' </sequence>

' The 32-byte private key is in the octets..
' Get it as hex.
Dim crypt As New ChilkatCrypt2
Dim privKeyHex As String
privKeyHex = crypt.ReEncode(xml.GetChildContent("octets"),"base64","hex")

Debug.Print "EC private key as hex = " & privKeyHex