(Visual Basic) Traverse Direct Children via FirstChild / NextSibling, or LastChild / PreviousSibling

Demonstrates some ways to iterate over direct child nodes using the FirstChild / NextSibling and LastChild / PreviousSibling methods.

The input XML, available at http://www.chilkatsoft.com/data/fruit.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

Download Chilkat XML ActiveX

Dim xml As New ChilkatXml
Dim child As ChilkatXml
Dim nextSibling As ChilkatXml
Dim prevSibling As ChilkatXml

Dim success As Long
'  The sample input XML is available at http://www.chilkatsoft.com/data/fruit.xml
success = xml.LoadXmlFile("fruit.xml")
If (success <> 1) Then
    Text1.Text = Text1.Text & xml.LastErrorText & vbCrLf
    Exit Sub
End If

'  Iterate over the direct children by using FirstChild / NextSibling
Set child = xml.FirstChild()
Do While Not (child Is Nothing )
    Text1.Text = Text1.Text & child.Tag & " : " _
         & child.Content & vbCrLf
    Set nextSibling = child.NextSibling()

    Set child = nextSibling
Loop
Text1.Text = Text1.Text & "-----" & vbCrLf

'  Do the same, but with FirstChild2 / NextSibling2 to avoid
'  creating so many XML object instances:
success = xml.FirstChild2()
Do While success = 1
    Text1.Text = Text1.Text & xml.Tag & " : " _
         & xml.Content & vbCrLf
    success = xml.NextSibling2()
Loop
'  Revert back up to the parent:
xml.GetParent2 

Text1.Text = Text1.Text & "-----" & vbCrLf

'  Iterate in reverse order using LastChild / PreviousSibling
Set child = xml.LastChild()
Do While Not (child Is Nothing )
    Text1.Text = Text1.Text & child.Tag & " : " _
         & child.Content & vbCrLf
    Set prevSibling = child.PreviousSibling()

    Set child = prevSibling
Loop
Text1.Text = Text1.Text & "-----" & vbCrLf

'  Do the same, but with LastChild2 / PreviousSibling2 to avoid
'  creating so many XML object instances:
success = xml.LastChild2()
Do While success = 1
    Text1.Text = Text1.Text & xml.Tag & " : " _
         & xml.Content & vbCrLf
    success = xml.PreviousSibling2()
Loop
'  Revert back up to the parent:
xml.GetParent2