(Visual Basic) Removing / Deleting Child Nodes from XML

Demonstrates various methods for removing child nodes from an XML document.

The input XML, available at http://www.chilkatsoft.com/data/fruit.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

Download Chilkat XML ActiveX

Dim xml As New ChilkatXml
Dim xyz As ChilkatXml

Dim success As Long
'  The sample input XML is available at http://www.chilkatsoft.com/data/fruit.xml
success = xml.LoadXmlFile("fruit.xml")
If (success <> 1) Then
    Text1.Text = Text1.Text & xml.LastErrorText & vbCrLf
    Exit Sub
End If

'  The RemoveChild method removes (discards) all direct
'  children having the specified tag:
xml.RemoveChild "fruit"

'  Show the resulting XML:
Text1.Text = Text1.Text & "Result with all direct children having a tag equal to ""fruit"" removed:" & vbCrLf
Text1.Text = Text1.Text & xml.GetXml() & vbCrLf

'  The XML with the "fruit" direct children removed is shown below:
'  Notice that the "fruit" node beneath "xyz" was not removed.
'  This correct because it was not a direct child of the calling node.
'  
<root>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <cheese color="yellow">cheddar</cheese>
</root>


'  --------------------------------------------------------------------------
'  Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

'  The RemoveChildWithContent method removes the child
'  having the exact content specified, regardless of the tag.
'  For example:
xml.RemoveChildWithContent "pear"

'  Show the resulting XML:
Text1.Text = Text1.Text & "Result with the node containing ""pear"" removed:" & vbCrLf
Text1.Text = Text1.Text & xml.GetXml() & vbCrLf

'  --------------------------------------------------------------------------
'  Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

'  The RemoveChildByIndex method removes the Nth direct
'  child.  Indexing begins at 0.  The "xyz" child is at index 4:
xml.RemoveChildByIndex 4

'  Show the resulting XML:
'  Notice that the entire "xyz" subtree is removed.
Text1.Text = Text1.Text & "Result with the node at index 4 removed:" & vbCrLf
Text1.Text = Text1.Text & xml.GetXml() & vbCrLf

'  --------------------------------------------------------------------------
'  Restore the original XML:
success = xml.LoadXmlFile("fruit.xml")

'  Navigate to the node with tag "xyz"
Set xyz = xml.FindChild("xyz")

'  Remove the "xyz" subtree making it it's own XML document
'  with the "xyz" node at the root:
xyz.RemoveFromTree 

'  Show both XML documents:
Text1.Text = Text1.Text & xyz.GetXml() & vbCrLf
Text1.Text = Text1.Text & xml.GetXml() & vbCrLf

'  Also, the TreeId property is an integer value assigned
'  to nodes in an XML document.  All nodes belonging to
'  the same XML document will have the same TreeId.
'  Notice that the "xyz" node now has a different TreeId:
Text1.Text = Text1.Text & "xyz TreeId = " & xyz.TreeId & vbCrLf
Text1.Text = Text1.Text & "xml TreeId = " & xml.TreeId & vbCrLf