Verify SSL Server Certificate

Demonstrates how to connect to an SSL server and verify its SSL certificate.

Download Chilkat Socket ActiveX

Dim socket As New ChilkatSocket

Dim success As Long
success = socket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    Exit Sub
End If

Dim ssl As Long
ssl = 1
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000

'  The SSL server hostname may be an IP address, a domain name,
'  or "localhost".
Dim sslServerHost As String
sslServerHost = "www.paypal.com"
Dim sslServerPort As Long
sslServerPort = 443

'  Connect to the SSL server:
success = socket.Connect(sslServerHost,sslServerPort,ssl,maxWaitMillisec)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    Exit Sub
End If

Dim cert As ChilkatCert

Dim bExpired As Long
Dim bRevoked As Long
Dim bSignatureVerified As Long
Dim bTrustedRoot As Long

Set cert = socket.GetSslServerCert()
If (Not (cert Is Nothing )) Then

    Text1.Text = Text1.Text & "Server Certificate:" & vbCrLf
    Text1.Text = Text1.Text & "Distinguished Name: " _
         & cert.SubjectDN & vbCrLf
    Text1.Text = Text1.Text & "Common Name: " _
         & cert.SubjectCN & vbCrLf
    Text1.Text = Text1.Text & "Issuer Distinguished Name: " _
         & cert.IssuerDN & vbCrLf
    Text1.Text = Text1.Text & "Issuer Common Name: " _
         & cert.IssuerCN & vbCrLf

    bExpired = cert.IsExpired()
    bRevoked = cert.Revoked
    bSignatureVerified = cert.SignatureVerified
    bTrustedRoot = cert.TrustedRoot

    Text1.Text = Text1.Text & "Expired: " & bExpired & vbCrLf
    Text1.Text = Text1.Text & "Revoked: " & bRevoked & vbCrLf
    Text1.Text = Text1.Text & "Signature Verified: " _
         & bSignatureVerified & vbCrLf
    Text1.Text = Text1.Text & "Trusted Root: " _
         & bTrustedRoot & vbCrLf

End If

'  Close the connection with the server
'  Wait a max of 20 seconds (20000 millsec)
socket.Close 20000