SSL Server Example

Demonstrates how to create an SSL socket for accepting connections. This example is *very* simple in that it will create an SSL socket for accepting a single connection. It will read a message from the client, send a reply, and exit.

Download Chilkat Socket ActiveX

Dim listenSslSocket As New ChilkatSocket

'  Any string automatically begins a fully-functional 30-day trial.
Dim success As Long
success = listenSslSocket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    Exit Sub
End If

'  An SSL server needs a digital certificate.  This example loads it from a PFX file.

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it.
'  (a PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

'  Find the certificate to be used for SSL:
Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

'  Use the certificate:
success = listenSslSocket.InitSslServer(cert)
If (success <> 1) Then
    MsgBox listenSslSocket.LastErrorText
    Exit Sub
End If

'  Bind and listen on a port:
Dim myPort As Long
myPort = 8123
'  Allow for a max of 5 queued connect requests.
Dim backLog As Long
backLog = 5
success = listenSslSocket.BindAndListen(myPort,backLog)
If (success <> 1) Then
    MsgBox listenSslSocket.LastErrorText
    Exit Sub
End If

'  Accept a single client connection:
Dim clientSock As ChilkatSocket
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000
Set clientSock = listenSslSocket.AcceptNextConnection(maxWaitMillisec)
If (clientSock Is Nothing ) Then
    MsgBox listenSslSocket.LastErrorText
    Exit Sub
End If

'  The client (in this example) is going to send a "Hello Server! -EOM-"
'  message.  Read it:
Dim receivedMsg As String
receivedMsg = clientSock.ReceiveUntilMatch("-EOM-")
If (receivedMsg = vbNullString ) Then
    MsgBox clientSock.LastErrorText
    Exit Sub
End If

MsgBox receivedMsg

'  Send a "Hello Client! -EOM-" message:
success = clientSock.SendString("Hello Client! -EOM-")
If (success <> 1) Then
    MsgBox clientSock.LastErrorText
    Exit Sub
End If

'  Close the connection with the client
'  Wait a max of 20 seconds (20000 millsec)
clientSock.Close 20000