SSL Client Certificate

Demonstrates how to connect to an SSL server using a client-side certificate, send a simple message, receive a simple response, and disconnect.

Download Chilkat Socket ActiveX

Dim socket As New ChilkatSocket

Dim success As Long
success = socket.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Failed to unlock component"
    Exit Sub
End If

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkat_secret.pfx","secret")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubjectCN("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

socket.SetSslClientCert cert

Dim ssl As Long
ssl = 1
Dim maxWaitMillisec As Long
maxWaitMillisec = 20000

'  The SSL server hostname may be an IP address, a domain name,
'  or "localhost".  You'll need to change this:
Dim sslServerHost As String
sslServerHost = "123.123.88.88"
Dim sslServerPort As Long
sslServerPort = 8123

'  Connect to the SSL server:
success = socket.Connect(sslServerHost,sslServerPort,ssl,maxWaitMillisec)
If (success <> 1) Then
    MsgBox socket.LastErrorText
    Exit Sub
End If

'  Set maximum timeouts for reading an writing (in millisec)
socket.MaxReadIdleMs = 20000
socket.MaxSendIdleMs = 20000

'  Send a "Hello Server! -EOM-" message:
success = socket.SendString("Hello Server! -EOM-")
If (success <> 1) Then
    MsgBox socket.LastErrorText
    Exit Sub
End If

'  The server (in this example) is going to send a "Hello Client! -EOM-"
'  message.  Read it:
Dim receivedMsg As String
receivedMsg = socket.ReceiveUntilMatch("-EOM-")
If (receivedMsg = vbNullString ) Then
    MsgBox socket.LastErrorText
    Exit Sub
End If

'  Close the connection with the server
'  Wait a max of 20 seconds (20000 millsec)
socket.Close 20000

MsgBox receivedMsg