SOAP Web Service (HTTP POST)

Demonstrates how to call PostXml to call a SOAP web service.

Download Chilkat XML ActiveX

Download Chilkat HTTP ActiveX

Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  This example uses a live web service at:
'  http://www.webservicex.net/uklocation.asmx
'  It gets the UK town,Postcode and County by Postcode(First Section of Post Code)

'  The SOAP XML will look like this:
'  <?xml version="1.0" encoding="utf-8"?>
'  <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
'    <soap:Body>
'      <GetUKLocationByPostCode xmlns="http://www.webserviceX.NET">
'        <PostCode>string</PostCode>
'      </GetUKLocationByPostCode>
'    </soap:Body>
'  </soap:Envelope>

'  For this example's sake, we'll load the XML from a file.  We'll test using PostCode "E3".
'  The SOAP XML for this example may be downloaded from:
'  http://www.chilkatsoft.com/testData/ukPostCodeSoap.xml
Dim xml As New ChilkatXml
success = xml.LoadXmlFile("ukPostCodeSoap.xml")
If (success <> 1) Then
    MsgBox xml.LastErrorText
    Exit Sub
End If

Dim strXml As String
strXml = xml.GetXml()

Dim resp As ChilkatHttpResponse
Dim responseStatusCode As Long

'  We'll need to add this in the HTTP header:
'  SOAPAction: "http://www.webserviceX.NET/GetUKLocationByPostCode"
http.SetRequestHeader "SOAPAction","http://www.webserviceX.NET/GetUKLocationByPostCode"

'  Some services expect the content-type in the HTTP header to be "application/xml" while
'  other expect text/xml.  The default sent by Chilkat is "application/xml", but this web service
'  expects "text/xml".  Therefore, change the content-type:
http.SetRequestHeader "Content-Type","text/xml; charset=utf-8"

'  The endpoint for this soap service is:
Dim endPoint As String
endPoint = "http://www.webservicex.net/uklocation.asmx"

'  Note: This particular web service was live and functioning at the time this example
'  was written.  It is possible that as time progresses, this web service will no longer
'  be availble...
Set resp = http.PostXml(endPoint,strXml,"utf-8")
If (resp Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf

    Text1.Text = Text1.Text & "LastHeader:" & vbCrLf
    Text1.Text = Text1.Text & http.LastHeader & vbCrLf
Else

    responseStatusCode = resp.StatusCode
    '  You may wish to verify that the responseStatusCode equals 200...
    Text1.Text = Text1.Text & "Response Status Code: " _
         & responseStatusCode & vbCrLf

    '  You may examine the exact HTTP header sent with the POST like this:
    Text1.Text = Text1.Text & "LastHeader:" & vbCrLf
    Text1.Text = Text1.Text & http.LastHeader & vbCrLf

    '  Examine the XML returned by the web service:
    Text1.Text = Text1.Text & "XML Response:" & vbCrLf
    Dim xmlResp As New ChilkatXml
    success = xmlResp.LoadXml(resp.BodyStr)
    '  Assume the LoadXml is successful...
    '  Get rid of the SOAP wrappings and get to the meat of this particular response.
    '  The TagContent method returns the content of the 1st node in the XML document
    '  having a specific tag:
    Dim unwrappedXml As String
    unwrappedXml = xmlResp.TagContent("GetUKLocationByPostCodeResult")
    Text1.Text = Text1.Text & unwrappedXml & vbCrLf

    '  The unwrapped XML could be loaded into an XML object and parsed...
    Dim xmlMeat As New ChilkatXml
    success = xmlMeat.LoadXml(unwrappedXml)

    '  ...
End If