Send Signed Email using PFX File

Demonstrates how to send a signed email using a digital certificate w/ private key stored in a PFX file.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.mymailserver.com"

'  Create a new email object
Dim email As New ChilkatEmail2

email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
email.AddTo "Chilkat Support","support@chilkatsoft.com"

'  Indicate that the email should be sent signed.
email.SendSigned = 1

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubjectE("admin@chilkatsoft.com")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

'  If a PFX file is known to contain a single certificate,
'  you may load it directly into a Chilkat certificate object.
'  This snippet of source code shows how:
Dim cert2 As New ChilkatCert
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = cert2.LoadPfxFile("chilkatsoft_secret.pfx","secret")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    Exit Sub
End If

'  This example will use the cert from the certStore...
email.SetSigningCert cert

'  Send a signed email.
success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    '  The LastErrorText property provides information
    '  even when successful.
    MsgBox mailman.LastErrorText
    MsgBox "Mail Sent!"
End If