Select Encryption Algorithm with SMTP Encrypted Email

Download Chilkat Email ActiveX

Demonstrates how to select the encryption algorithm and strength (key size) when sending encrypted email.

'  The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Create a new email object
Dim email As New ChilkatEmail2

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

'  In this example, we've already installed the certificate for "admin@chilkatsoft.com"
'  in the current user's personal certificate store.
'  If the email.SendEncrypted property is set, Chilkat will
'  automatically search for and use the first non-expired certificate
'  matching the recipient's email address.  Chilkat searches
'  the Current User's Personal certificate store, as well
'  as the Local Machine's Personal certificate store.
'  Run certmgr.msc to view the certs in the Current User's
'  certificate store.
email.SendEncrypted = 1

'  Use the CSP object to select an encryption algorithm:
Dim csp As New ChilkatCSP
'  Make sure we're using the enhanced provider, which provides
'  access to stronger algorithms.
csp.SetProviderMicrosoftEnhanced 

'  Select 168-bit 3DES (i.e. 192-bit DES if you include the parity bits)
csp.SetEncryptAlgorithm "3DES"

'  Tell the email to use this CSP:
email.SetCSP csp

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    '  Examine the LastErrorText anyway, so we can see
    '  that 3DES was used...
    '  You should see these lines in the log:
    '  alg_name: 3DES
    '  alg_bits: 168
    MsgBox mailman.LastErrorText
End If