Verify S/MIME Signature

Visual Basic example to verify an S/MIME signature and unwrap the S/MIME to get the original MIME prior to signing/encrypting.

Dim mime As New ChilkatMime

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mime.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "MIME component unlock failed"
    Exit Sub
End If

'  Load an S/MIME message from a file:
success = mime.LoadMimeFile("signedMime.txt")
If (success <> 1) Then
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  The ContainsEncryptedParts/ContainsSignedParts methods
'  can be called to determine if the MIME is encrypted and/or signed:
Dim isEncrypted As Long
isEncrypted = mime.ContainsEncryptedParts()
Dim isSigned As Long
isSigned = mime.ContainsSignedParts()

'  We don't want the "unwrap extras".  You'll see what those
'  are in a few moments...
mime.UnwrapExtras = 0

'  To verify the signature, call UnwrapSecurity.  This will
'  verify the signature(s) and decrypt the S/MIME and restore
'  the MIME to the unsigned/unencrypted state.
'  The results of what was found are present in the MIME object's
'  properties, as well as extra header fields that are added
'  to the unwrapped MIME.
success = mime.UnwrapSecurity()
If (success <> 1) Then
    '  UnwrapSecurity returns _TRUE_ if all signatures were
    '  verified and all parts decrypted.
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  The mime.UnwrapExtras property controls whether or not
'  these additional fields are added to the unwrapped MIME:
' 
'  X-NumPartsSigned: 1
'  X-SignaturesValid: yes
'  X-NumPartsEncrypted: 1
'  X-Decrypted: no
' 
'  The X-NumPartsSigned/X-SignaturesValid headers are added
'  if the MIME was signed.
' 
'  The X-NumPartsEncrypted/X-Decrypted headers are added
'  if the MIME was encrypted.
' 

'  If the MIME was signed, get the certificate used for signing.
If (isSigned = 1) Then
    '  The NumSignerCerts property indicates how many certificates
    '  were used for signing.  This example will assume the value is 1.
    '  To get the 1st signer cert, call GetSignerCert with an index of 0:
    Dim signerCert As ChilkatCert
    Set signerCert = mime.GetSignerCert(0)
    If (Not (signerCert Is Nothing )) Then
        Text1.Text = Text1.Text & "**** Signer Cert: " _
             & signerCert.SubjectCN & vbCrLf
        Text1.Refresh
    End If

End If

'  If the MIME was encrypted, get the certificate used for encryption:
If (isEncrypted = 1) Then
    '  The NumEncryptCerts property indicates how many certificates
    '  were used for encrypting.  This example will assume the value is 1.
    '  To get the 1st encrypt cert, call GetEncryptCert with an index of 0:
    Dim encryptCert As ChilkatCert
    Set encryptCert = mime.GetEncryptCert(0)
    If (Not (encryptCert Is Nothing )) Then
        Text1.Text = Text1.Text & "**** Encrypt Cert: " _
             & encryptCert.SubjectCN & vbCrLf
        Text1.Refresh
    End If

End If

'  Display the unwrapped MIME:
Text1.Text = Text1.Text & mime.GetMime() & vbCrLf
Text1.Refresh

'  Save the unwrapped MIME to a file:
mime.SaveMime "unwrappedMime.txt"