SFTP Read Text File to String

Demonstrates how to download a text file from an SSH server directly into a string variable.

Download Chilkat SSH / SFTP ActiveX

'  Important: It is helpful to send the contents of the
'  sftp.LastErrorText property when requesting support.

Dim sftp As New ChilkatSFtp

'  Any string automatically begins a fully-functional 30-day trial.
Dim success As Long
success = sftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 15000

'  Connect to the SSH server.
'  The standard SSH port = 22
'  The hostname may be a hostname or IP address.
Dim port As Long
Dim hostname As String
hostname = "www.my-ssh-server.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Authenticate with the SSH server.  Chilkat SFTP supports
'  both password-based authenication as well as public-key
'  authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Open a file on the server:
Dim handle As String
handle = sftp.OpenFile("hamlet.xml","readOnly","openExisting")
If (handle = vbNullString ) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Get the total size of this file (in bytes)
Dim bFollowLinks As Long
bFollowLinks = 0
Dim bIsHandle As Long
bIsHandle = 1
Dim numBytes As Long

'  bFollowLinks is ignored because we are passing a handle
'  and not a remote filename.
'  There are atlernative methods for handling file sizes
'  greater than 32-bit.  (See the reference documentation.)
numBytes = sftp.GetFileSize32(handle,bFollowLinks,bIsHandle)
If (numBytes < 0) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  The charset indicates the character encoding of the text
'  file on the SSH server.   Setting the charset correctly
'  allows the Chilkat SFTP component to correctly interpret
'  the bytes that represent the characters.
Dim charset As String
charset = "ansi"
Dim offset32 As Long
offset32 = 0
Dim fileContents As String
fileContents = sftp.ReadFileText32(handle,offset32,numBytes,charset)
If (fileContents = vbNullString ) Then
    MsgBox sftp.LastErrorText
    Exit Sub
Else
    Text1.Text = Text1.Text & "Received file:" & vbCrLf
    Text1.Text = Text1.Text & fileContents & vbCrLf
End If

'  Close the file.
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

MsgBox "Success."