SFTP Read Directory Listing

Demonstrates how to download a directory listing and iterate over the files.

Download Chilkat SSH / SFTP ActiveX

'  Important: It is helpful to send the contents of the
'  sftp.LastErrorText property when requesting support.

Dim sftp As New ChilkatSFtp

'  Any string automatically begins a fully-functional 30-day trial.
Dim success As Long
success = sftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

'  Connect to the SSH server.
'  The standard SSH port = 22
'  The hostname may be a hostname or IP address.
Dim port As Long
Dim hostname As String
hostname = "www.my-sftp-server.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Authenticate with the SSH server.  Chilkat SFTP supports
'  both password-based authenication as well as public-key
'  authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Open a directory on the server...
'  Paths starting with a slash are "absolute", and are relative
'  to the root of the file system. Names starting with any other
'  character are relative to the user's default directory (home directory).
'  A path component of ".." refers to the parent directory,
'  and "." refers to the current directory.
Dim handle As String
handle = sftp.OpenDir(".")
If (handle = vbNullString ) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Download the directory listing:
Dim dirListing As ChilkatSFtpDir
Set dirListing = sftp.ReadDir(handle)
If (dirListing Is Nothing ) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

'  Iterate over the files.
Dim i As Long
Dim n As Long
n = dirListing.NumFilesAndDirs
If (n = 0) Then
    Text1.Text = Text1.Text & "No entries found in this directory." & vbCrLf
Else
    For i = 0 To n - 1
        Dim fileObj As ChilkatSFtpFile
        Set fileObj = dirListing.GetFileObject(i)

        Text1.Text = Text1.Text & fileObj.Filename & vbCrLf
        Text1.Text = Text1.Text & fileObj.FileType & vbCrLf
        Text1.Text = Text1.Text & "Size in bytes: " _
             & fileObj.Size32 & vbCrLf
        Text1.Text = Text1.Text & "----" & vbCrLf

    Next
End If

'  Close the directory
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    Exit Sub
End If

MsgBox "Success."