Send Email and Save Copy to "Sent" Mailbox

Sends an email and places a copy in the "Sent" mailbox on an IMAP server.

This example demonstrates how to send an email and then upload a copy to an IMAP mail server's "Sent" mailbox. Note: You may need to create a "Sent" mailbox on your IMAP server prior to running this example. You may already have a mailbox named something different -- perhaps "Sent Items".

Important: If your mail server is POP3, the "Sent Items" mailbox is actually a file on your local computer managed by your email client, such as Outlook, Mozilla Thunderbird. This example does not save emails to Outlook or Mozilla Thunderbird "Sent Items" local files.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the SMTP server.
mailman.SmtpHost = "mail.chilkatsoft.com"
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
Dim email As New ChilkatEmail2

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"

    '  Now use Chilkat IMAP to save the email to Inbox.Sent

    Dim imap As New ChilkatImap

    '  Anything unlocks the component and begins a fully-functional 30-day trial.
    success = imap.UnlockComponent("Anything for 30-day trial")
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        Exit Sub
    End If

    '  Connect to an IMAP server.
    success = imap.Connect("mail.chilkatsoft.com")
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        Exit Sub
    End If

    '  Login
    success = imap.Login("myLogin","myPassword")
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        Exit Sub
    End If

    '  The AppendMail method uploads an email to an IMAP server
    '  and saves it in the mailbox specified:
    success = imap.AppendMail("Inbox.Sent",email)
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        Exit Sub
    End If

    MsgBox "Mail saved to Inbox.Sent"
End If