RSA Encrypt and Decrypt Strings

Download Chilkat RSA ActiveX

Visual Basic sample code to RSA public-key encrypt and decrypt strings using public and private keys.

Dim rsa As New ChilkatRsa

Dim success As Long
success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    Exit Sub
End If

'  This example also generates the public and private
'  keys to be used in the RSA encryption.
'  Normally, you would generate a key pair once,
'  and distribute the public key to your partner.
'  Anything encrypted with the public key can be
'  decrypted with the private key.  The reverse is
'  also true: anything encrypted using the private
'  key can be decrypted using the public key.

'  Generate a 1024-bit key.  Chilkat RSA supports
'  key sizes ranging from 512 bits to 16384 bits.
success = rsa.GenerateKey(1024)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    Exit Sub
End If

'  Keys are exported in XML format:
Dim publicKey As String
publicKey = rsa.ExportPublicKey()
Dim privateKey As String
privateKey = rsa.ExportPrivateKey()

Dim plainText As String
plainText = "Encrypting and decrypting should be easy!"

'  Start with a new RSA object to demonstrate that all we
'  need are the keys previously exported:
Dim rsaEncryptor As New ChilkatRsa

'  Encrypted output is always binary.  In this case, we want
'  to encode the encrypted bytes in a printable string.
'  Our choices are "hex", "base64", "url", "quoted-printable".
rsaEncryptor.EncodingMode = "hex"

'  We'll encrypt with the public key and decrypt with the private
'  key.  It's also possible to do the reverse.
rsaEncryptor.ImportPublicKey publicKey

Dim usePrivateKey As Long
usePrivateKey = 0
Dim encryptedStr As String
encryptedStr = rsaEncryptor.EncryptStringENC(plainText,usePrivateKey)
Text1.Text = Text1.Text & encryptedStr & vbCrLf
Text1.Refresh

'  Now decrypt:
Dim rsaDecryptor As New ChilkatRsa

rsaDecryptor.EncodingMode = "hex"
rsaDecryptor.ImportPrivateKey privateKey

usePrivateKey = 1
Dim decryptedStr As String
decryptedStr = rsaDecryptor.DecryptStringENC(encryptedStr,usePrivateKey)

Text1.Text = Text1.Text & decryptedStr & vbCrLf
Text1.Refresh