RSA Encrypt/Decrypt AES Key

Demonstrates how to use RSA to protect a key for AES encryption. It can be used in this scenario: You will provide your RSA public key to any number of counterparts. Your counterpart will generate an AES key, encrypt data (or a file) using it, then encrypt the AES key using your RSA public key. Your counterpart sends you both the encrypted data and the encrypted key. Since you are the only one with access to the RSA private key, only you can decrypt the AES key. You decrypt the key, then decrypt the data using the AES key.

This example will show the entire process. (1) Generate an RSA key and save both private and public parts to PEM files. (2) Encrypt a file using a randomly generated AES encryption key. (3) RSA encrypt the AES key. (4) RSA decrypt the AES key. (5) Use it to AES decrypt the file or data.

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Download Chilkat Crypt ActiveX

' 
'   This example requires two Chilkat licenses:  RSA and Crypt.
' 

'  ------------------
'  Step 1.  Generate an RSA key and save to PEM files.

Dim rsa As New ChilkatRsa

Dim success As Long
success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Text1.Text = Text1.Text & rsa.LastErrorText & vbCrLf
    Exit Sub
End If

'  Generate a 1024-bit key.  Chilkat RSA supports
'  key sizes ranging from 512 bits to 4096 bits.
success = rsa.GenerateKey(1024)
If (success <> 1) Then
    Text1.Text = Text1.Text & rsa.LastErrorText & vbCrLf
    Exit Sub
End If

'  Keys are exported in XML format:
Dim pubKeyXml As String
pubKeyXml = rsa.ExportPublicKey()

Dim pubKey As New PublicKey
success = pubKey.LoadXml(pubKeyXml)
'  For brevity, we are not checking the return value...
success = pubKey.SaveOpenSslPemFile("pubKey.pem")

Dim privKeyXml As String
privKeyXml = rsa.ExportPrivateKey()

Dim privKey As New PrivateKey
success = privKey.LoadXml(privKeyXml)
success = privKey.SaveRsaPemFile("privKey.pem")

'  Other methods exist for saving the private key in PKCS8 format,
'  both encrypted and un-encrypted..

'  ------------------
'  Step 2.   This is the code your counterpart will run to
'  AES encrypt a file.  It generates a random AES key
'  to use for the encryption.

Dim crypt As New ChilkatCrypt2

success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Text1.Text = Text1.Text & crypt.LastErrorText & vbCrLf
    Exit Sub
End If

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 256

'  Generate random bytes and return the random bytes
'  in a hex string:
crypt.EncodingMode = "hex"
Dim randomKey As String
randomKey = crypt.GenRandomBytesENC(32)

'  Set the key.
crypt.SetEncodedKey randomKey,"hex"

'  Set the IV to a known value that will be used on both sides.
'  (If desired, you could generate a random IV and protect it in the same
'  way as the key...)
'  The length of the IV for AES is always 16 bytes, regardless of the key size.
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

'  AES Encrypt the file (the file may be any size because it will
'  stream the file in/out.
success = crypt.CkEncryptFile("hamlet.xml","aesEncrypted.dat")
If (success <> 1) Then
    Text1.Text = Text1.Text & crypt.LastErrorText & vbCrLf
    Exit Sub
End If

'  ------------------
'  Step 3.
'  ------------------
'  RSA encrypt the AES key.
'  We'll pretend  your counter part has the public-key PEM file and needs
'  to load it.  Therefore, we'll start with a new RSA object and load
'  the public key from the PEM..
Dim rsa2 As New ChilkatRsa
Dim pubKey2 As New PublicKey

'  For brevity, don't check the success..
success = pubKey2.LoadOpenSslPemFile("pubKey.pem")
pubKeyXml = pubKey2.GetXml()
success = rsa2.ImportPublicKey(pubKeyXml)

'  RSA encrypt the AES key and return it as a base64 encoded string.
rsa2.EncodingMode = "base64"
Dim bUsePrivateKey As Long
bUsePrivateKey = 0
Dim encryptedAesKey As String
encryptedAesKey = rsa2.EncryptStringENC(randomKey,bUsePrivateKey)

'  At this point, your counterpart sends you the encryptedAesKey,
'  and the encrypted file.

'  ------------------
'  Step 4 - RSA decrypt the AES key.
'  ------------------

'  Start with a new RSA object and load the private key from the PEM.
Dim rsa3 As New ChilkatRsa
Dim privKey2 As New PrivateKey

success = privKey2.LoadPemFile("privKey.pem")
privKeyXml = privKey2.GetXml()
success = rsa3.ImportPrivateKey(privKeyXml)

'  The encrypted AES key is encoded using base64, so set
'  our EncodingMode to "base64".
rsa3.EncodingMode = "base64"

bUsePrivateKey = 1
Dim decryptedAesKey As String
decryptedAesKey = rsa3.DecryptStringENC(encryptedAesKey,bUsePrivateKey)

'  ------------------
'  Step 5 - AES decrypt the file.
'  ------------------

Dim crypt2 As New ChilkatCrypt2

crypt2.CryptAlgorithm = "aes"
crypt2.CipherMode = "cbc"
crypt2.KeyLength = 256

'  Set the key.
crypt2.SetEncodedKey decryptedAesKey,"hex"

'  Set the IV
crypt2.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

'  AES Decrypt the file (the file may be any size because it will
'  stream the file in/out.
success = crypt2.CkDecryptFile("aesEncrypted.dat","decrypted.xml")
If (success <> 1) Then
    Text1.Text = Text1.Text & crypt2.LastErrorText & vbCrLf
    Exit Sub
End If