RSA Encrypt and Decrypt Credit Card Numbers

Visual Basic sample code to RSA public-key encrypt and decrypt credit card numbers. The RSA key is loaded from an unencrypted PKCS8 file. Chilkat provides many ways of setting the key -- loading from both encrypted and unencrypted PEM, PKCS8, DER, PVK, etc. Keys may be loaded from files or in-memory representations. (The RSA component also provides the ability to generate RSA keys.)

Download Chilkat RSA ActiveX

Dim rsa As New ChilkatRsa

Dim success As Long
success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    Exit Sub
End If

Dim key As New PrivateKey

'  Load an RSA private key from a PKCS8 file:
success = key.LoadPkcs8File("rsaPrivateKey.p8")
If (success <> 1) Then
    MsgBox key.LastErrorText
    Exit Sub
End If

'  Get the key as XML:
Dim keyXml As String
keyXml = key.GetXml()

'  We'll encrypt with the public key and decrypt with the private
'  key.  (It's also possible to do the reverse.)
'  Note: An RSA private key is composed of different parts internally: modulus, exponent, P, Q, etc.
'  An RSA public-key is a sub-set of the private key.
'  Therefore, when you have a private key, you really have
'  both public and private keys.
success = rsa.ImportPublicKey(keyXml)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    Exit Sub
End If

'  Encrypt a VISA credit card number:
'  1234-5678-0000-9999
Dim ccNumber As String
ccNumber = "1234567800009999"

Dim usePrivateKey As Long
usePrivateKey = 0
rsa.EncodingMode = "base64"
Dim encryptedStr As String
encryptedStr = rsa.EncryptStringENC(ccNumber,usePrivateKey)
Text1.Text = Text1.Text & "Encrypted:" & vbCrLf
Text1.Text = Text1.Text & encryptedStr & vbCrLf

'  Now decrypt:
Dim rsaDecryptor As New ChilkatRsa

rsaDecryptor.EncodingMode = "base64"
rsaDecryptor.ImportPrivateKey keyXml

usePrivateKey = 1
Dim decryptedStr As String
decryptedStr = rsaDecryptor.DecryptStringENC(encryptedStr,usePrivateKey)

Text1.Text = Text1.Text & "Decrypted:" & vbCrLf
Text1.Text = Text1.Text & decryptedStr & vbCrLf

'  Important: RSA encryption should only be used to encrypt small amounts of data.
'  It is typically used for encrypting symmetric encryption
'  keys such that a symmetric encryption algorithm, such as
'  AES is then used to encrypt/decrypt bulk data.