PPMD String Compression

Demonstrates string compression using PPMD.

Download Chilkat Compression ActiveX

Dim compress As New ChilkatCompression

'  Any string argument automatically begins a 30-day trial.
Dim success As Long
success = compress.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Compression component unlock failed"
    Exit Sub
End If

compress.Algorithm = "ppmd"

Dim strData As String
Dim i As Long

'  Create a long string to compress.
strData = "abcdefg1122334455667788"
strData = strData & vbCrLf
For i = 0 To 99
    strData = strData & "abcdefg1122334455667788"
    strData = strData & vbCrLf
Next

'  Depending on the programming language, the string
'  may be Unicode.  Tell the component to convert to
'  ansi (1-byte/char) prior to compression:
compress.Charset = "ansi"

'  Compressed data is binary, meaning that all byte values
'  from 0 to 255 are possible.  The result would not be
'  a printable string.  To receive a printable string (us-ascii),
'  the resultant compressed data should be encoded using
'  an encoding such as base64.  Set the EncodingMode
'  property to determine the output encoding:
'  (Valid choices are "base64", "hex", "url", and others)
compress.EncodingMode = "base64"

'  Note: Base64 encoding expands the compressed data by
'  4/3rds because each 3 bytes of binary data are represented
'  by 4 printable chars.  Hex, for example, doubles the output
'  size because each byte is represented by 2 printable chars.

'  PPMD compress the string:
Dim compressedStr As String
compressedStr = compress.CompressStringENC(strData)
If (compressedStr = vbNullString ) Then
    MsgBox compress.LastErrorText
    Exit Sub
End If

'  Display the compressed string.
'  The result will be:
'  ec8YZ5vk9za18d0plwuV7R65em9OZge9gJXht/QAAAAAAAAAABNOZQAAKw==
Text1.Text = Text1.Text & compressedStr & vbCrLf

'  Decompress back to the original:
Dim strOriginal As String
strOriginal = compress.DecompressStringENC(compressedStr)

'  Display the uncompressed original:
Text1.Text = Text1.Text & "--- Original ---" & vbCrLf
Text1.Text = Text1.Text & strOriginal & vbCrLf