PPMD Streaming String Compression

Demonstrates streaming string compression using PPMD. Data may be compressed in chunks by initially calling one of the BeginCompress* methods, followed by 0 or more calls to a MoreCompress* method, and terminating with a call to an EndCompress* method.

Likewise, data may be decompressed by calling a BeginDecompress* method, followed by 0 or more MoreDecompress* calls, and ending with an EndDecompress* method call.

This example demonstrates string-to-string compression and decompression in chunks.

Download Chilkat Compression ActiveX

Dim compress As New ChilkatCompression

'  Any string argument automatically begins a 30-day trial.
Dim success As Long
success = compress.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Compression component unlock failed"
    Exit Sub
End If

compress.Algorithm = "ppmd"
compress.Charset = "ansi"
compress.EncodingMode = "base64"

Dim strData As String
Dim i As Long

Dim strCompressed As String

'  Create a long string to compress.
strData = "abcdefg1122334455667788"
strData = strData & vbCrLf

'  Note: BeginCompressStringENC may return a zero-length
'  string.  This is normal if the input is buffered and no
'  compressed data is yet available.
'  However, a null reference indicates an error -- which is
'  generally only possible if the component was never unlocked.
strCompressed = compress.BeginCompressStringENC(strData)

'  Compress 100 more chunks of data.  Each call to
'  MoreCompressStringENC may or may not produce additional
'  compressed output.
For i = 0 To 99
    strData = "abcdefg1122334455667788"
    strData = strData & vbCrLf

    strCompressed = strCompressed & compress.MoreCompressStringENC(strData)
Next

'  Finalize the compression with a single call to EndCompressStringENC:
strCompressed = strCompressed & compress.EndCompressStringENC()

'  Display the compressed string.
'  The result will be:
'  ec8YZ5vk9za18d0plwuV7R65em9OZge9gJXht/QAAAAAAAAAABNOZQAAKw==

Text1.Text = Text1.Text & strCompressed & vbCrLf

'  Decompress back to the original in a single call.
Dim strOriginal As String
strOriginal = compress.DecompressStringENC(strCompressed)

'  Display the uncompressed original:
Text1.Text = Text1.Text & "--- Original ---" & vbCrLf
Text1.Text = Text1.Text & strOriginal & vbCrLf

'  Decompress in multiple calls.  It doesn't matter how the
'  compressed data is split -- it could be fed to the decompressor
'  one char at a time if desired.
Dim chunk1 As String
chunk1 = "ec8YZ5vk9za1"
Dim chunk2 As String
chunk2 = "8d0p"
Dim chunk3 As String
chunk3 = "lwuV7R65em9OZge9gJXht/QAAAA"
Dim chunk4 As String
chunk4 = "AAAAAABNOZQAAKw=="

strOriginal = ""
strOriginal = compress.BeginDecompressStringENC(chunk1)
strOriginal = strOriginal & compress.MoreDecompressStringENC(chunk2)
strOriginal = strOriginal & compress.MoreDecompressStringENC(chunk3)
strOriginal = strOriginal & compress.MoreDecompressStringENC(chunk4)
strOriginal = strOriginal & compress.EndDecompressStringENC()

'  Display the uncompressed original after decompressing in chunks:
Text1.Text = Text1.Text & "--- Original after Decompressing from Chunks ---" & vbCrLf
Text1.Text = Text1.Text & strOriginal & vbCrLf