Reading Unread POP3 Email

The POP3 protocol does not provide the ability to ask the server which emails are "unread". Furthermore, a pure POP3 server does not even keep this information. Some servers, such as Exchange Server, expose both POP3 and IMAP interfaces. In these cases, information about read/unread status exists on the server, but it is only available via the IMAP protocol. Email clients such as Outlook and Thunderbird keep read/unread information on the client computer. This example demonstrates how UIDLs can be saved to track and read "unread" email.

Download Chilkat Email ActiveX

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "***"
mailman.PopPassword = "***"

'  You may keep a list of already-seen UIDLs in a text file:
'  If this is the first time you're running this example,
'  create an empty text file named "seenUidls.txt"
Dim saSeenUidls As New CkStringArray
success = saSeenUidls.LoadFromFile("seenUidls.txt")
If (success <> 1) Then
    MsgBox "failed to load seenUidls.txt"
    Exit Sub
End If

'  Get the complete list of UIDLs on the mail server.
Dim saUidls As CkStringArray
Set saUidls = mailman.GetUidls()

If (saUidls Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

'  Create a new string array object (it's an object, not an actual array)
'  and add the UIDLs from saUidls that aren't already seen.
Dim saUnseenUidls As New CkStringArray

Dim i As Long
Dim n As Long
n = saUidls.Count
For i = 0 To n - 1
    If (saSeenUidls.Contains(saUidls.GetString(i)) <> 1) Then
        saUnseenUidls.Append saUidls.GetString(i)
    End If

Next

If (saUnseenUidls.Count = 0) Then
    MsgBox "No unseen emails!"

    Exit Sub
End If

'  Download in full the unseen emails:
Dim bundle As ChilkatEmailBundle2

Set bundle = mailman.FetchMultiple(saUnseenUidls)
If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText

    Exit Sub
End If

Dim email As ChilkatEmail2
For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)
    Text1.Text = Text1.Text & email.From & vbCrLf
    Text1.Text = Text1.Text & email.Subject & vbCrLf
    Text1.Text = Text1.Text & "----" & vbCrLf

Next

'  Save saUidls to "seenUidls.txt"
saUidls.SaveToFile "seenUidls.txt"