POP3: Download Most Recent Email (method 2)

How to ready the N most recent email from a POP3 server.

The POP3 protocol does not provide the ability to request the most recent email, nor does it provide the ability to download email based on read/unread status or any other criteria. The design principle behind POP3 is that it is a temporary holding store for incoming email and email clients or other applications will transfer email from the POP3 server to a local persistent store where it will be managed. Therefore, POP3 does not provide sophisticated functionality (as opposed to IMAP which has the opposite design philosophy: that email is maintained and organized on the server).

This example shows one possible way to retrieve the N most recent emails from a POP3 server. It downloads the complete list of UIDLs and then downloads the last N into a bundle object. It assumes that the UIDLs will be returned by the POP3 server ordered by date such that the 1st email in the UIDL list is the oldest, and the last email is the newest.

Download Chilkat Email ActiveX for POP3 / SMTP

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "admin@chilkatsoft.com"
mailman.PopPassword = "****"

Dim saUidls As CkStringArray
'  Get the complete list of UIDLs
Set saUidls = mailman.GetUidls()

If (saUidls Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

'  Get the 10 most recent UIDLs
'  The 1st email is the oldest, the last email is the newest
'  (usually)
Dim i As Long
Dim n As Long
Dim startIdx As Long
n = saUidls.Count
If (n > 10) Then
    startIdx = n - 10
Else
    startIdx = 0
End If

Dim saUidls2 As New CkStringArray
For i = startIdx To n - 1
    saUidls2.Append saUidls.GetString(i)
Next

'  Download in full the 10 most recent emails:
Dim bundle As ChilkatEmailBundle2

Set bundle = mailman.FetchMultiple(saUidls2)
If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

Dim email As ChilkatEmail2
For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)
    Text1.Text = Text1.Text & email.From & vbCrLf
    Text1.Refresh
    Text1.Text = Text1.Text & email.Subject & vbCrLf
    Text1.Refresh
    Text1.Text = Text1.Text & "----" & vbCrLf
    Text1.Refresh

Next