POP3: Download Most Recent Email (method 1)

Download Chilkat Email ActiveX

How to ready the N most recent email from a POP3 server.

The POP3 protocol does not provide the ability to request the most recent email, nor does it provide the ability to download email based on read/unread status or any other criteria. The design principle behind POP3 is that it is a temporary holding store for incoming email and email clients or other applications will transfer email from the POP3 server to a local persistent store where it will be managed. Therefore, POP3 does not provide sophisticated functionality (as opposed to IMAP which has the opposite design philosophy: that email is maintained and organized on the server).

This example shows one possible way to retrieve the N most recent emails from a POP3 server. It downloads the headers into a bundle object, then sorts the bundle by date, and finally retrieves the most recent emails by UIDL.

Another alternative is to download the UIDL list and then assume that the 1st N UIDLs are the most recent.

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "admin@chilkatsoft.com"
mailman.PopPassword = "*myPassword5*"

Dim bundle As ChilkatEmailBundle2
'  Read mail headers and one line of the body.
Set bundle = mailman.GetAllHeaders(1)

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

'  Sort the bundle by date
Dim ascending As Long
ascending = 0
bundle.SortByDate ascending

'  Get the 10 most recent UIDLs
Dim saUidls As New CkStringArray
Dim i As Long
Dim n As Long
n = bundle.MessageCount
If (n > 10) Then
    n = 10
End If

Dim email As ChilkatEmail2
For i = 0 To n - 1
    Set email = bundle.GetEmail(i)
    saUidls.Append email.Uidl

Next

'  Download in full the 10 most recent emails:
Dim bundle2 As ChilkatEmailBundle2

Set bundle2 = mailman.FetchMultiple(saUidls)
If (bundle2 Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

For i = 0 To bundle2.MessageCount - 1
    Set email = bundle2.GetEmail(i)
    Text1.Text = Text1.Text & email.From & vbCrLf
    Text1.Refresh
    Text1.Text = Text1.Text & email.Subject & vbCrLf
    Text1.Refresh
    Text1.Text = Text1.Text & "----" & vbCrLf
    Text1.Refresh

Next