POP3 using HTTP Proxy

Demonstrates how to communicate with a POP3 server through an HTTP proxy.

Download Chilkat Email ActiveX

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  To connect through an HTTP proxy, set the HttpProxyHostname
'  and HttpProxyPort properties to the hostname (or IP address)
'  and port of the HTTP proxy.  Typical port numbers used by
'  HTTP proxy servers are 3128 and 8080.
mailman.HttpProxyHostname = "www.my-http-proxy.com"
mailman.HttpProxyPort = 3128

'  Important:  Your HTTP proxy server must allow non-HTTP
'  traffic to pass.  Otherwise this does not work.

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

Dim bundle As ChilkatEmailBundle2
'  Copy the all email from the user's POP3 mailbox
'  into a bundle object.  The email remains on the server.
' 
'  NOTE: All methods that communicate with a POP3 server
'  will automatically connect and authenticate (i.e. login)
'  if not already connected.  The connection will remain
'  open after the method call returns so that subsequent
'  calls do not need to re-establish the connection.
'  In this case, the connection is established via the HTTP
'  proxy.
Set bundle = mailman.CopyMail()

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

Dim i As Long
Dim email As ChilkatEmail2
For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)
    Text1.Text = Text1.Text & email.From & vbCrLf
    Text1.Text = Text1.Text & email.Subject & vbCrLf & vbCrLf

Next

mailman.Pop3EndSession