POP3 to SMTP Forwarder

Read a POP3 mailbox and forwards the email to another email address, keeping the recipients in the original email the same.

Download Chilkat Email ActiveX for POP3 / SMTP

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
Dim mailman As New ChilkatMailMan2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    Exit Sub
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "matt@chilkatsoft.com"
mailman.PopPassword = "****"

Dim saUidls As CkStringArray

'  The the UIDLs for all email in the POP3 mailbox.
Set saUidls = mailman.GetUidls()
If (saUidls Is Nothing ) Then
    MsgBox mailman.LastErrorText
    Exit Sub
End If

Dim saMime As CkStringArray

'  Download the email from the server.  Call FetchMultipleMime
'  because we don't want to load the emails into email objects.
'  (We'll delete the emails that are forwarded without error.)
Set saMime = mailman.FetchMultipleMime(saUidls)

If (saMime Is Nothing ) Then

    MsgBox mailman.LastErrorText
    Exit Sub
End If

'  Set the SMTP hostname for sending.
mailman.SmtpHost = "mail.chilkatsoft.com"
mailman.SmtpUsername = "admin@chilkatsoft.com"
mailman.SmtpPassword = "****"

Dim i As Long
Dim strMime As String
Dim n As Long
n = saMime.Count

Dim fromAddr As String
Dim toAddr As String
fromAddr = "matt@chilkatsoft.com"
toAddr = "admin@chilkatsoft.com"

Dim bAllOk As Long
bAllOk = 1

If (n > 0) Then
    For i = 0 To n - 1

        strMime = saMime.GetString(i)

        '  Forward the email.
        success = mailman.SendMime(fromAddr,toAddr,strMime)
        If (success <> 1) Then
            bAllOk = 0
            Text1.Text = Text1.Text & mailman.LastErrorText & vbCrLf
            Exit For
        End If

    Next
End If

'  Remove the emails in saUidls from the POP3 server.
If (bAllOk = 1) Then
    success = mailman.DeleteMultiple(saUidls)
    If (success <> 1) Then
        Text1.Text = Text1.Text & mailman.LastErrorText & vbCrLf
    End If

End If