PKCS7 SignedData Detached Signature

How to create a PKCS7 detached signature. The resulting PKCS7 structure is encoded to a printable string using hex or base64 encoding. The data being signed is not included in the PKCS#7 structure.

Download Chilkat Crypt ActiveX

Dim crypt As New ChilkatCrypt2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

Dim cert As New ChilkatCert
success = cert.LoadByCommonName("Chilkat Software")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    Exit Sub
End If

'  Make sure this certificate has a private key available:
Dim bHasPrivateKey As Long
bHasPrivateKey = cert.HasPrivateKey()
If (bHasPrivateKey <> 1) Then
    MsgBox "No private key available for signing."
    Exit Sub
End If

'  Tell the encryption component to use this cert.
crypt.SetSigningCert cert

Dim strData As String
strData = "This is the data to be signed."

'  Indicate that the PKCS7 signature should be returned
'  as a base64 encoded string:
crypt.EncodingMode = "base64"

'  The EncodingMode may be set to other values such as
'  "hex", "url", "quoted-printable", etc.

Dim strSignature As String
strSignature = crypt.SignStringENC(strData)

Text1.Text = Text1.Text & strSignature & vbCrLf

'  Now verify the signature against the original data.

'  Tell the component what certificate to use for verification.
crypt.SetVerifyCert cert

success = crypt.VerifyStringENC(strData,strSignature)
If (success = 1) Then
    MsgBox "digital signature verified"
Else
    MsgBox "digital signature invalid"
End If

'  Try it with incorrect data:
success = crypt.VerifyStringENC("This is not the signed data",strSignature)
If (success = 1) Then
    MsgBox "digital signature verified"
Else
    MsgBox "digital signature invalid"
End If