Unwrap S/MIME Security Layers

Download Chilkat MIME ActiveX

Demonstrates how to unwrap the security layers of a signed and/or encrypted S/MIME message.

Dim i As Long
Dim mime As New ChilkatMime

Dim success As Long
success = mime.UnlockComponent("Anything for 30-day trial")
If (success = 0) Then
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  Note: Your S/MIME file may have a different file extension.
success = mime.LoadMimeFile("smime.eml")
If (success = 0) Then
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  Unwrap any security layers so that the resultant MIME
'  is the original message before signing and/or encrypting
'  was applied.  UnwrapSecurity returns 1 if
'  there was nothing to unwrap, or if all signatures were verified,
'  and all decryptions succeeded.
success = mime.UnwrapSecurity()
If (success = 0) Then
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  Save the unwrapped S/MIME:
success = mime.SaveMime("unwrapped.eml")
If (success = 0) Then
    MsgBox mime.LastErrorText
    Exit Sub
End If

'  Let's see if the MIME was signed, and if so whether
'  the signature(s) were verified.  Also, examine the certificate
'  used for signing.
Dim cert As ChilkatCert

'  Unwrapping the security sets the NumSignerCerts property.
'  If it is non-zero, then signatures were unwrapped...
Text1.Text = Text1.Text & "Signer Certificates: " & vbCrLf
Dim numSignerCerts As Long
numSignerCerts = mime.NumSignerCerts
If (numSignerCerts > 0) Then
    For i = 0 To numSignerCerts - 1
        Set cert = mime.GetSignerCert(i)
        If (Not (cert Is Nothing )) Then
            '  Show the cert's common name.
            Text1.Text = Text1.Text & cert.SubjectCN & vbCrLf
        End If

    Next
End If

'  Now check to see if anything was decrypted.
Text1.Text = Text1.Text & "Encryption Certificates: " & vbCrLf
Dim numEncryptCerts As Long
numEncryptCerts = mime.NumEncryptCerts
If (numEncryptCerts > 0) Then
    For i = 0 To numEncryptCerts - 1
        Set cert = mime.GetEncryptCert(i)
        If (Not (cert Is Nothing )) Then
            '  Show the cert's common name.
            Text1.Text = Text1.Text & cert.SubjectCN & vbCrLf
        End If

    Next
End If