Using Client Certificate w/ IMAP SSL

Demonstrates how to use a client-side certificate with an IMAP SSL connection. The SetSslClientCert method is called to specify a certificate to be used for the SSL connection.

Download Chilkat IMAP ActiveX

Dim imap As New ChilkatImap

Dim success As Long

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  To use a secure SSL connection, set SSL and the port:
imap.Ssl = 1
'  The typical port for IMAP SSL is 993
imap.Port = 993

'  Load a certificate from a PFX file and use it.
'  Note: Other methods are available to load pre-installed
'  certificates from registry-based certificate stores.

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
Dim certStore As New ChilkatCertStore
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("myCertWithPrivateKey.pfx","secret")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

'  Find the certificate by the subject common name:
Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubjectCN("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

'  If a PFX file is known to contain a single certificate,
'  you may load it directly into a Chilkat certificate object.
'  This snippet of source code shows how:
Dim cert2 As New ChilkatCert
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = cert2.LoadPfxFile("tagtooga_secret.pfx","secret")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    Exit Sub
End If

'  Use the cert:
imap.SetSslClientCert cert

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

Dim messageSet As MessageSet
'  We can choose to fetch UIDs or sequence numbers.
Dim fetchUids As Long
fetchUids = 1
'  Get the message IDs of all the emails in the mailbox
Set messageSet = imap.Search("ALL",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Fetch the emails into a bundle object:
Dim bundle As ChilkatEmailBundle2
Set bundle = imap.FetchBundle(messageSet)
If (bundle Is Nothing ) Then

    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Loop over the bundle and display the FROM and SUBJECT of each.
Dim i As Long
For i = 0 To bundle.MessageCount - 1
    Dim email As ChilkatEmail2
    Set email = bundle.GetEmail(i)
    Text1.Text = Text1.Text & email.From & vbCrLf
    Text1.Text = Text1.Text & email.Subject & vbCrLf
    Text1.Text = Text1.Text & "--" & vbCrLf

Next

'  Disconnect from the IMAP server.
imap.Disconnect