Delete IMAP Email

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

To delete an email, the "Deleted" flag must be set to 1 for each message to be deleted. You must also call Expunge or ExpungeAndClose to remove the emails marked as deleted.

'  This example deletes email matching a criteria from Inbox.
Dim imap As New ChilkatImap

Dim success As Long

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Turn on session logging:
imap.KeepSessionLog = 1

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

Dim messageSet As MessageSet
Dim fetchUids As Long
fetchUids = 1
'  Get the message IDs for all emails having "FTP2" in the subject.
Set messageSet = imap.Search("SUBJECT FTP2",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Set the Deleted flag for each message:
success = imap.SetFlags(messageSet,"Deleted",1)
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Expunge and close the mailbox.
success = imap.ExpungeAndClose()
If (success <> 1) Then
    MsgBox imap.LastErrorText
    Exit Sub
End If

'  Display the session log.
Text1.Text = Text1.Text & imap.SessionLog & vbCrLf

'  Disconnect from the IMAP server.
imap.Disconnect