Read IMAP Email Flags

VB6 sample code showing how to download email headers from an IMAP server and read the seen, deleted, answered, and draft flags.

' Read email from an IMAP server and determine if an
' email is:
' 1) New (hasn't been seen)
' 2) Marked for deletion
' 3) Answered
' 4) Draft
Private Sub Command1_Click()

    ' Create an object, connect to the IMAP server, login,
    ' and select a mailbox.
    Dim imap As New ChilkatImap
    imap.UnlockComponent "UnlockCode"
    imap.Connect "www.mymailserver.com"
    imap.Login "login", "password"
    imap.SelectMailbox "Inbox"
    
    ' Get a message set containing all the message IDs
    ' in the selected mailbox.
    Dim msgSet As messageSet
    Set msgSet = imap.Search("ALL", 1)
    
    ' Fetch all the mail headers into a bundle object.
    Dim bundle As New ChilkatEmailBundle2
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Loop over the bundle and display the From and Subject.
    Dim email As ChilkatEmail2
    Dim descrip As String
    For i = 0 To bundle.MessageCount - 1
    
        ' This email object only contains the header because
        ' we fetched the email using FetchHeaders.
        Set email = bundle.GetEmail(i)
        
        descrip = "("
        
        If (imap.GetMailFlag(email, "Seen") = 1) Then
            descrip = descrip & "Seen, "
        Else
            descrip = descrip & "NOT Seen, "
        End If
        
        If (imap.GetMailFlag(email, "Deleted") = 1) Then
            descrip = descrip & "Marked for Deletion, "
        Else
            descrip = descrip & "NOT Marked for Deletion, "
        End If
        
        If (imap.GetMailFlag(email, "Answered") = 1) Then
            descrip = descrip & "Answered, "
        Else
            descrip = descrip & "NOT Answered, "
        End If
        
        If (imap.GetMailFlag(email, "Draft") = 1) Then
            descrip = descrip & "Draft"
        Else
            descrip = descrip & "NOT a Draft"
        End If
        
        descrip = descrip & ")"
        
        descrip = descrip & email.From & ": " & email.Subject
        
        ' We can always synchronize the flags in our local email object
        ' with the current state of the flags for the email on the IMAP server
        ' by calling RefetchMailFlags...
        ' Example: status = imap.RefetchMailFlags(email)
        
        List1.AddItem descrip
    Next
        
    ' Disconnect from the IMAP server.
    ' This example leaves the email on the IMAP server.
    imap.Disconnect
    
    
End Sub