(Visual Basic) Send XMLHttpRequest using PUT, GET, DELETE, or any HTTP Request Method

The PostXml method is the easiest way to send an XMLHttpRequest using the POST HTTP verb (which is by far the most common). To use a different HTTP request method (such as PUT, GET, DELETE, etc.), the SynchronousRequest method should be called. It provides more flexibility in constructing the exact HTTP request desired.

Download Chilkat HTTP ActiveX

Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Exit Sub
End If

'  The XML sent in the body of the request is application
'  specified -- it should contain whatever the server-side
'  application is expecting..
Dim xmlStr As String
xmlStr = "<?xml version=""1.0"" encoding=""UTF-8""?><appXml><something>123</something></appXml>"

'  If the service endpoint is  "http://www.chilkatsoft.com/xmlEcho.asp",
'  then we have the following arguments to be passed to
'  SynchronousRequest:
Dim endpointDomain As String
endpointDomain = "www.chilkatsoft.com"
Dim endpointPort As Long
endpointPort = 80
Dim endpointSsl As Long
endpointSsl = 0

'  Prepare the HTTP request object:
Dim request As New ChilkatHttpRequest
request.Path = "/xmlEcho.asp"

'  This example will use the "PUT" HTTP request method
'  (also known as HTTP verb)
request.HttpVerb = "PUT"
request.ContentType = "text/xml"
request.Charset = "utf-8"
request.LoadBodyFromString xmlStr,"utf-8"

Dim response As ChilkatHttpResponse
Set response = http.SynchronousRequest(endpointDomain,endpointPort,endpointSsl,request)
If (response Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Exit Sub
End If

'  The raw HTTP request sent by the above call is:
'  
PUT /xmlEcho.asp HTTP/1.1
Content-Type: text/xml
Host: www.chilkatsoft.com
Content-Length: 81

<?xml version="1.0" encoding="UTF-8"?><appXml><something>123</something></appXml>


'  Examine the Body of the HTTP response
'  This would be the XML response sent by the server.
Text1.Text = Text1.Text & response.BodyStr & vbCrLf