HTTP Session with Cookies

How to keep a session with cookies. Demonstrates how to login to WordPress.

Download Chilkat HTTP ActiveX

Dim req As New ChilkatHttpRequest
Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  This example will demonstrate maintaining a session with
'  cookies by doing a simple login to a WordPress blog.
'  Indicate that cookies are to be saved and re-sent.
'  Instead of using a cookie file, you may use the string "memory"
'  to save cookies to memory.
http.CookieDir = "memory"
http.SendCookies = 1
http.SaveCookies = 1

'  Let's first hit the chilkat.wordpress.com login page to make sure
'  we have any initial cookies...
Dim html As String
html = http.QuickGetStr("http://chilkat.wordpress.com/wp-login.php")
If (html = vbNullString ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Text1.Refresh
    Exit Sub
End If

'  Build an HTTP POST request to login
req.UsePost 
req.Path = "/wp-login.php"
req.AddParam "log","chilkat"
req.AddParam "pwd","myPassword"
req.AddParam "rememberme","forever"
req.AddParam "wp-submit","Login"
req.AddParam "redirect_to","/wp-admin/"

req.AddHeader "Referer","http://chilkat.wordpress.com/wp-login.php"

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.
Dim domain As String
Dim port As Long
Dim ssl As Long
domain = "chilkat.wordpress.com"
port = 80
ssl = 0
Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Text1.Refresh
    Exit Sub
End If

'  Is this a 302 redirect?
If (resp.StatusCode = 302) Then

    '  Get the redirect URL:
    Dim redirectUrl As String
    redirectUrl = resp.GetHeaderField("Location")

    html = http.QuickGetStr(redirectUrl)
    If (html = vbNullString ) Then
        Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
        Text1.Refresh
    Else
        Text1.Text = Text1.Text & html & vbCrLf
        Text1.Refresh
    End If

Else
    Text1.Text = Text1.Text & resp.BodyStr & vbCrLf
    Text1.Refresh
End If