HTTPS Form Login

Using the del.icio.us site, demonstrates how to programmatically login via a form.

Download Chilkat HTTP ActiveX

Dim req As New ChilkatHttpRequest
Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  Cookies may be persisted to a directory in the filesystem,
'  or alternatively cached in memory by using the "memory"
'  keyword:
http.CookieDir = "memory"
'  Accumulated cookies are sent with each GET/POST:
http.SaveCookies = 1
'  Cookies received in HTTP responses are to be saved:
http.SendCookies = 1

'  Get the page with the login form.  We're only doing this
'  just in case there are cookies that need to be cached
'  and re-sent in the next step:
Dim html As String
html = http.QuickGetStr("https://secure.del.icio.us/login")
If (http.LastStatus <> 200) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  Examining the "Page Info" in FireFox reveals a form with
'  a target of https://secure.del.icio.us/login with
'  fields of "user_name", "password", and "login".  The "login"
'  field is nothing more than the submit button and holds
'  the value "log in".

'  Build an HTTP POST Request:
req.UsePost 
req.Path = "/login"
req.AddParam "user_name","chilkatsoft"
req.AddParam "password","****"
req.AddParam "login","log in"

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.
Dim domain As String
Dim port As Long
Dim ssl As Long
domain = "secure.del.icio.us"
port = 443
ssl = 1
Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Text1.Refresh
Else
    Dim responseStatus As Long
    responseStatus = resp.StatusCode
    If (responseStatus = 302) Then

        '  We have a redirect.  Follow it...
        '  Note: the FollowRedirects property causes
        '  301/302 responses to GET requests to be
        '  automatically followed.
        http.FollowRedirects = 1
        html = http.QuickGetStr(resp.GetHeaderField("Location"))
        If (http.LastStatus <> 200) Then
            MsgBox http.LastErrorText
            Exit Sub
        End If

    Else
        html = resp.BodyStr
    End If

    Text1.Text = Text1.Text & responseStatus & vbCrLf
    Text1.Refresh

    '  Display the HTML source of the page returned.
    Text1.Text = Text1.Text & html & vbCrLf
    Text1.Refresh

End If