HTTP GET - Download and Parse HTML

Downloads an HTML page from the Singapore Exchange and parses a row of options prices from an HTML table.

Download Chilkat XML ActiveX

Download Chilkat HTTP ActiveX

Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  Send the HTTP GET and return the content in a string.
Dim html As String
html = http.QuickGetStr("http://esite.sgx.com/live/dt/DTFuture.asp?JBFE")

'  Use the Chilkat HTML-to-XML component to convert
'  the HTML to parsable XML:
Dim htmlToXml As New HtmlToXml

'  Any string argument automatically begins the 30-day trial.

success = htmlToXml.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "HtmlToXml component unlock failed"
    Exit Sub
End If

'  Indicate the charset of the output XML we'll want.
htmlToXml.XmlCharset = "utf-8"

'  Set the HTML:
htmlToXml.Html = html

'  We won't need the scripts or images, so drop those tags...
htmlToXml.DropTagType "img"
htmlToXml.DropTagType "script"

'  Get the XML:
Dim xmlStr As String
xmlStr = htmlToXml.ToXml()

'  Load the XML into the Chilkat XML parser:
Dim xml As New ChilkatXml
xml.LoadXml xmlStr

'  success = xml.SaveXml("out.xml");

Dim node As ChilkatXml

'  Find a known point in the XML.  In this case we'll look for the text node
'  containing this string: "Chg From Prev Settle"
Set node = xml.SearchForContent(Nothing,"text","Chg From Prev Settle")
If (node Is Nothing ) Then
    MsgBox "Did not find Chg From Prev Settle"
    Exit Sub
End If

'  Move up to the TD node:
node.GetParent2 

'  Move up to the TR node:
node.GetParent2 

'  Move to the next row (i.e. next TR)
node.NextSibling2 

node.FirstChild2 
node.NextSibling2 

Text1.Text = Text1.Text & "Expire Month/Year: " _
     & node.GetChildContent("text") & vbCrLf
node.NextSibling2 

Text1.Text = Text1.Text & "Last: " & node.GetChildContent("text") & vbCrLf
node.NextSibling2 

Text1.Text = Text1.Text & "Change: " & node.GetChildContent("text") & vbCrLf
node.NextSibling2 

'  ...

success = node.SaveXml("row.xml")