(Visual Basic) Adding Cookies to an HTTP Request

Demonstrates how to add one or more cookies to an HTTP request. For Chilkat HTTP methods that use an HTTP request object, such as SynchronousRequest or PostUrlEncoded, cookies are added by calling the AddHeader method on the request object. For Chilkat HTTP methods that do not use an HTTP request object, such as QuickGetStr, cookies are added by calling AddQuickHeader.

Download Chilkat HTTP ActiveX

Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Exit Sub
End If

'  The Cookie header field has this format:
'  Cookie: name1=value1 [; name2=value2] ...

'  Build an HTTP POST request:
Dim request As New ChilkatHttpRequest
request.SetFromUrl "http://www.chilkatsoft.com/echoPost.asp"
request.HttpVerb = "POST"

request.AddParam "param1","value1"
request.AddParam "param2","value2"

'  To add cookies to any HTTP request sent by a Chilkat HTTP method
'  that uses an HTTP request object, add the cookies to the
'  request object by calling AddHeader.

'  Add two cookies:
request.AddHeader "Cookie","user=""mary""; city=""Chicago"""

'  Send the HTTP POST.
'  (The cookies are sent as part of the HTTP header.)

Dim response As ChilkatHttpResponse
Dim domain As String
domain = "www.chilkatsoft.com"
Dim port As Long
port = 80
Dim ssl As Long
ssl = 0
Set response = http.SynchronousRequest(domain,port,ssl,request)
If (response Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
    Exit Sub
End If

'  Display the HTML body of the response.
If (response.StatusCode = 200) Then
    '  Show the last HTTP request header sent, which should include
    '  our cookies...
    Text1.Text = Text1.Text & http.LastHeader & vbCrLf
Else
    Text1.Text = Text1.Text & "HTTP Response Status = " _
         & response.StatusCode & vbCrLf
End If

Text1.Text = Text1.Text & "---------------------" & vbCrLf

'  Some Chilkat HTTP methods do not use an HTTP request object.
'  For these methods, such as for QuickGetStr, cookies (or any HTTP request header)
'  are added by calling AddQuickHeader.
http.AddQuickHeader "Cookie","user=""mary""; city=""Chicago"""

Dim html As String
html = http.QuickGetStr("http://www.w3.org/")
If (html = vbNullString ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
Else
    '  Show the last HTTP request header sent, which should include
    '  our cookies...
    Text1.Text = Text1.Text & http.LastHeader & vbCrLf
End If