Secure FTP with Client Certificate

Chilkat FTP2 provides the ability to use a client certificate with secure FTP (implicit or explicit SSL/TLS). This example demonstrates how to load a certificate from a .pfx and use it as the client-side SSL cert. Note: Client-side certificates are only needed in situations where the server demands one.

Download 32-bit Chilkat FTP2 ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim ftp As New ChilkatFtp2

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

ftp.Hostname = "ftp.***.com"
ftp.Port = 21
ftp.Username = "test"
ftp.Password = "test"

'  This example will use explict TLS/SSL.
'  Establish an explicit secure channel after connection
'  on the standard FTP port 21.
ftp.AuthTls = 1

'  The Ssl property is for establishing an implicit SSL connection
'  on port 990.  Because this example uses explicit SSL, it
'  should remain 0.
ftp.Ssl = 0

'  Load a certificate from a .pfx
'  A PFX may contain several certs, including the certificates
'  in a chain of authority.
Dim certStore As New ChilkatCertStore
Dim password As String
password = "***"
'  Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("chilkat.pfx",password)
If (success <> 1) Then
    Text1.Text = Text1.Text & certStore.LastErrorText & vbCrLf
    Exit Sub
End If

'  Find the exact cert we'll use:
Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    Text1.Text = Text1.Text & "Certificate not found!" & vbCrLf
    Exit Sub
End If

'  Use this certificate for our secure (SSL/TLS) connection:
ftp.SetSslClientCert cert

'  Connect and login to the FTP server.  The connection is
'  made secure because of the AuthTls setting.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
Else
    '  LastErrorText contains information even when
    '  successful. This allows you to visually verify
    '  that the secure connection actually occurred.
    Text1.Text = Text1.Text & ftp.LastErrorText & vbCrLf
End If

MsgBox "Secure FTP Channel Established!"

'  Do whatever you're doing to do ...
'  upload files, download files, etc...

'  .....
'  .....

ftp.Disconnect