FTP Upload Encrypted and Compressed

Compress and encrypt a file, and upload it to an FTP server. Then do the reverse (download, decrypt, inflate).

Download Chilkat FTP2 ActiveX

Download Chilkat Crypt ActiveX

Dim ftp As New ChilkatFtp2

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

Dim crypt As New ChilkatCrypt2

'  Any string unlocks the component for the 1st 30-days.
success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    Exit Sub
End If

ftp.Hostname = "www.example-code.com"
ftp.Username = "***"
ftp.Password = "***"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Read the file into memory.
Dim fileData As New ByteData
Set fileData = crypt.ReadFile("hamlet.xml")
If (fileData Is Nothing ) Then
    MsgBox crypt.LastErrorText
    Exit Sub
End If

Dim compressedData As New ByteData
Set compressedData = crypt.CompressBytes(fileData)

'  Use 128-bit AES encryption, in CBC mode.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "0123456789ABCDEF","ascii"
crypt.SetEncodedIV "0123456789ABCDEF","ascii"

Dim encryptedData As New ByteData
Set encryptedData = crypt.EncryptBytes(compressedData)

'  Upload from a byte array.
Dim remoteFilename As String
remoteFilename = "hamlet.dat"

success = ftp.PutFileFromBinaryData(remoteFilename,encryptedData)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Now do the reverse:
Dim encryptedData2 As New ByteData
Set encryptedData2 = ftp.GetRemoteFileBinaryData(remoteFilename)
If (encryptedData2 Is Nothing ) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Decrypt:
Dim decryptedData As New ByteData
Set decryptedData = crypt.DecryptBytes(encryptedData2)

'  Inflate:
Dim inflatedData As New ByteData
Set inflatedData = crypt.InflateBytes(decryptedData)

'  Save the decrypted/inflated data to a file.
success = crypt.WriteFile("hamlet2.xml",inflatedData)
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    Exit Sub
End If

ftp.Disconnect 

MsgBox "File Uploaded and Downloaded!"