Download and Delete Matching Files

Visual Basic example showing how to FTP download files matching a wildcarded file pattern and delete them from the FTP server.

Download Chilkat FTP2 ActiveX

Dim ftp As New ChilkatFtp2

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

ftp.Hostname = "www.example-code.com"
ftp.Username = "****"
ftp.Password = "****"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Note: It may be tempting to call MGetFiles(pattern,localDir)
'  followed by a call to DeleteMatching(pattern), however,
'  if new files are uploaded to the FTP server while MGetFiles
'  is running, those files will be deleted by DeleteMatching.

'  Instead, it's best to set the ListPattern and then iterate
'  over each file...

'  Set the ListPattern = "*.xml" to match all XML files.
ftp.ListPattern = "*.xml"

'  NumFilesAndDirs contains the number of files and sub-directories
'  matching the ListPattern in the current remote directory.
'  The first time it is accessed after changing ListPattern,
'  or after calling ChangeRemoteDir, a snapshot of the directory
'  listing is fetched and saved in memory. During this loop,
'  the value of NumFilesAndDirs will not change.
Dim i As Long
Dim fname As String

Dim n As Long
n = ftp.NumFilesAndDirs
If (n < 0) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

If (n > 0) Then
    For i = 0 To n - 1

        fname = ftp.GetFilename(i)
        Text1.Text = Text1.Text & fname & vbCrLf

        '  Download the file into the current working directory.
        success = ftp.GetFile(fname,fname)
        If (success <> 1) Then
            MsgBox ftp.LastErrorText
            Exit Sub
        End If

        '  Now delete the file.
        success = ftp.DeleteRemoteFile(fname)
        If (success <> 1) Then
            MsgBox ftp.LastErrorText
            Exit Sub
        End If

    Next
End If

ftp.Disconnect