Directory Existence Check

How to test if a directory exists on an FTP server.

A good way to check to see if a directory already exists is to try to "cd" to that remote directory by calling ChangeRemoteDir. If it succeeds, then the directory exists. If not, then it does not exist. An alternative method is to set the ListPattern = "*" and then iterate over the files/directories, looking for the directory.

Download Chilkat FTP2 ActiveX

Dim ftp As New ChilkatFtp2

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

ftp.Hostname = "ftp.chilkatsoft.com"
ftp.Username = "***"
ftp.Password = "***"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

'  Does the "temp" directory exist?
Dim dirExists As Long
dirExists = ftp.ChangeRemoteDir("/temp")
If (dirExists = 1) Then
    MsgBox "Yes, the temp directory exists."
    '   Yes, it exists. Restore the current remote dir:
    success = ftp.ChangeRemoteDir("..")
    If (success <> 1) Then
        MsgBox ftp.LastErrorText
        Exit Sub
    End If

End If

'  Alternatively, you may set the ListPattern = "*" and
'   look for the directory:
ftp.ListPattern = "*"

Dim i As Long
Dim n As Long
n = ftp.NumFilesAndDirs
If (n < 0) Then
    '  Failed to get directory listing based on ListPattern
    MsgBox ftp.LastErrorText
    Exit Sub
End If

Dim foundDir As Long
foundDir = 0
If (n > 0) Then
    For i = 0 To n - 1
        Dim isDir As Long
        isDir = ftp.GetIsDirectory(i)
        If (isDir = 1) Then
            Dim fname As String
            fname = ftp.GetFilename(i)
            If (fname = "temp") Then
                MsgBox "Found temp directory!"
                foundDir = 1
                Exit For
            End If

        End If

    Next
End If

If (foundDir <> 1) Then
    MsgBox "temp directory not found!"
End If

ftp.Disconnect